Beginning with SAS 9.2, some common allocation methods, including proportional allocation, are available in PROC SURVEYSELECT. Prior to SAS 9.2, you can manually allocate your total sample size according to specified proportions to achieve this result. In proportional allocation, the sampling fraction in each stratum reflects the same sampling fraction as in the population. That is, n_h/N_h is equal to n/N for every stratum h.

Here is an example using PROC SURVEYSELECT. Suppose you have three groups and a total of 3000 observations:

      data a;
        do i=1 to 3000;
          if ranuni(2345) le .4 then Group=1;
            else if ranuni(2345) ge .8 then Group=2;
            else Group=3;
          output;
        end;
        run;

Suppose further that you want a simple random sample of 10 observations such that the group proportions in the sample are the same as the group proportions in the original population.

For convenience, set a macro variable to your total sample size.

      %let TotalSampleSize=10;

To have the same or nearly the same sample and population stratum proportions, you’ll compute the necessary stratum sample sizes and pass them to PROC SURVEYSELECT. First, determine the population stratum proportions and save them to a data set.

      title "Group distribution in the population";
      proc freq data=a;
        tables Group / out=freqout;
        run;
      title;

The results in this example are as follows:

Group distribution in the population The FREQ Procedure Group Frequency Percent Cumulative Frequency Cumulative Percent 1 1190 39.67 1190 39.67 2 375 12.50 1565 52.17 3 1435 47.83 3000 100.00

For the sample to retain this distribution, you want 39.67% of the sample to be in Group 1; 12.5% in Group 2; and 47.83% in Group 3. So, the sample sizes to select from the groups are as follows:

Group 1 Sample Size = 0.3967 * 10 ≈ 3.97

Group 2 Sample Size = 0.1250 * 10 = 1.25

Group 3 Sample Size = 0.4783 * 10 ≈ 4.78

Because the sample sizes must be integers, use a rounding or truncating function when computing the stratum sample sizes. This next DATA step creates a SAMPSIZE= input data set for PROC SURVEYSELECT, and computes the proportionally allocated stratum sample sizes.

      data sampsize;
        set freqout;
        _nsize_=round((Percent/100) * &TotalSampleSize);
        run;

Sort your DATA= data set by the stratum variable if it's not already sorted. To use PROC SURVEYSELECT correctly for stratified sampling, the DATA= data set and SAMPSIZE= value list or data set must have the strata in the same order.

      proc sort data=a;
        by group;
        run;

And finally, select the sample.

      proc surveyselect data=a out=sample sampsize=sampsize;
        strata Group;
        run;

If you want to verify the distribution of the sample, use PROC FREQ.

      title "Group distribution in the sample";
      proc freq data=sample;
        tables Group;
        run;
      title;

The desired result is achieved:

Group distribution in the sample The FREQ Procedure Group Frequency Percent Cumulative Frequency Cumulative Percent 1 4 40.00 4 40.00 2 1 10.00 5 50.00 3 5 50.00 10 100.00

The overall sampling fraction of 10/3000 = 0.0033 has been retained as closely as possible in each stratum. We have stratum sampling fractions of 4/1190 = 0.0034, 1/375 = 0.0027, and 5/1435 = 0.0035.

This same approach can be easily extended to two or more strata. For example, suppose you want a sample of 25 observations from the following data set of 500, such that the proportions of males and females in each of three age groups are the same as the population proportions.

      data b;
        do id=1 to 500;
          Gender=scan('male, female', ceil(2*ranuni(430982)));
          AgeGroup=scan('18-25,25-50,Over 50', rantbl(839247,0.20,0.50,0.30),',');
          output;
        end;
      run;

      %let TotalSampSize = 25;

      title "Gender and Age Group distribution in the population";
      proc freq data=b;
        tables Gender*AgeGroup / out=freqout;
      run;
      title;

Gender and Age Group distribution in the population The FREQ Procedure Frequency Percent Row Pct Col Pct Table of Gender by AgeGroup Gender AgeGroup Total 18-25 25-50 Over 50 female 52 10.40 21.31 48.15 113 22.60 46.31 47.68 79 15.80 32.38 50.97 244 48.80     male 56 11.20 21.88 51.85 124 24.80 48.44 52.32 76 15.20 29.69 49.03 256 51.20     Total 108 21.60 237 47.40 155 31.00 500 100.00

      data sampsize;
        set freqout;
        _nsize_=round((Percent/100) * &TotalSampSize);
      run;

      proc sort data=b;
        by Gender AgeGroup;
      run;
      proc surveyselect data=b out=sample sampsize=sampsize noprint;
        strata Gender AgeGroup;
      run;

      title "Gender and Age Group distribution in the sample";
      proc freq data=sample;
        tables Gender * AgeGroup;
      run;
      title;

Notice that the final sample size is 26 in this example instead of the intended size of 25. This is due to the necessary rounding in the _NSIZE_ computation. The _NSIZE_ computations prior to rounding result in stratum sampling fractions equal to the overall sampling fraction. Because integer sample sizes are required, the final sample size will be as close as possible to the specified sample size while maintaining stratum sampling fractions as close as possible to the overall sampling fraction.

Gender and Age Group distribution in the sample The FREQ Procedure Frequency Percent Row Pct Col Pct Table of Gender by AgeGroup Gender AgeGroup Total 18-25 25-50 Over 50 female 3 11.54 23.08 50.00 6 23.08 46.15 50.00 4 15.38 30.77 50.00 13 50.00     male 3 11.54 23.08 50.00 6 23.08 46.15 50.00 4 15.38 30.77 50.00 13 50.00     Total 6 23.08 12 46.15 8 30.77 26 100.00

Operating System and Release Information

Product Family	Product	System	SAS Release
			Reported	Fixed*
SAS System	SAS/STAT	All	n/a

* For software releases that are not yet generally available, the Fixed Release is the software release in which the problem is planned to be fixed.

---

Type:	Usage Note
Priority:	low
Topic:	Analytics ==> Survey Sampling and Analysis SAS Reference ==> Procedures ==> SURVEYSELECT

Date Modified:	2017-05-18 15:49:01
Date Created:	2007-03-12 15:27:38