The FLYOVER= attribute adds the HTML attribute TITLE= to the HTML source to display the specified text when the user's mouse hovers over the tagged text. The TITLE= attribute does not allow any style information, so changing the fonts and colors are not possible. But you do have some formatting choices.

For example, you can break the flyover text into multiple lines for easier reading. To do this, add carriage-return line-feed characters in the value before you add it to the FLYOVER= attribute. This can be done easily with formats. On the PC, the output of the example code below displays the flyover on two separate lines where age is equal to 11. The examples below also work when using the FLYOVER= attribute in the PDF destination.

  proc format;
     value test 11="This" "0D0A"x "test";
  run;

  ods html file="tmep.html";

  proc print data=sashelp.class;
     var age / style={flyover=test.};
  run;

  ods html close;

You can also make the FLYOVER= attribute more dynamic by adding a format as an argument to the attribute, or by adding another variable as the argument to the FLYOVER= attribute. For instance, in the below example, some text is added before the value of another cell which is displayed when hovered over. This is done by building the value in the FLYOVER= attribute within the CALL DEFINE statement. View output.

  ods html file="c:\flyover.html";

  proc report data=sashelp.class nowd;
     title "Flyover dynamic text";
     title2;
  column name age sex  height weight;
  compute sex;
     call define(_col_,"style",
          "style={flyover='The value is "||trim(left(age.sum))||"'}");
  endcomp;
  run;

  ods html close;

See also the full PROC TEMPLATE FAQ and Concepts.

Operating System and Release Information