Usage Note 22590: Standardized coefficients and confidence intervals for regression models
 |  |  |  |
Standardized coefficients are often used as a way to assess the relative importance of model effects. Unlike the regular, unstandardized model coefficients, the standardized coefficients can be directly compared to find the largest ones (in absolute value), which represent the most important predictors. They measure the change in the response for a one standard deviation change in the predictor while the other predictors are held fixed. This, and other ways of assessing variable importance in an ordinary regression model and in generalized linear models, are discussed in SAS Note 22605.
Standardized regression coefficients can be obtained for models fit with the REG and GLMSELECT procedures by specifying the STB option in the MODEL statement and in the GLIMMIX procedure with the STDCOEF option in its MODEL statement. The GLM procedure does not have an option to compute standardized parameter estimates. For PROC REG which, unlike other regression procedures, does not support the CLASS statement, additional steps are needed to obtain standardized coefficients when the model contains categorical variables. You must first fit the model in a procedure that can save the design matrix in a data set as discussed in SAS KB0057012. You can then fit the model in PROC REG by specifying the individual design variables in the MODEL statement. The standardized estimates are produced by specifying the STB option.
You can also use any of several other regression procedures (including GLM, ORTHOREG, and others) to obtain standardized coefficients if you first standardize the data. Use the STANDARD procedure to standardize the response and design variables. When you then use a regression procedure to fit the model to the standardized data, the resulting parameter estimates are standardized coefficients. Additionally, in procedures that support an option that provides confidence limits on the parameter estimates, using the option produces confidence limits for the standardized coefficients when modeling standardized data. For example, you can specify the CLPARM option in the MODEL statement in PROC GLM, or the CLB option in the MODEL statement in PROC REG.
The following statements demonstrate the methods described above.
data plants;
input type $ @;
do block=1 to 3;
input stemleng @;
output;
end;
datalines;
clarion 32.7 32.3 31.5
clinton 32.1 29.7 29.1
knox 35.7 35.9 33.1
o'neill 36.0 34.2 31.2
compost 31.8 28.0 29.2
wabash 38.2 37.8 31.9
webster 32.5 31.1 29.7
;
PROC GLM can only compute the unstandardized estimates from the raw data. The SOLUTION option displays the estimates.
title 'GLM: unstandardized estimates';
ods select ParameterEstimates;
proc glm data=plants;
class type block;
model stemleng = type block / solution;
run; quit;
The STB option in PROC GLMSELECT computes both the unstandardized and standardized estimates.
title 'GLMSELECT: unstandardized and standardized estimates';
ods select ParameterEstimates;
proc glmselect data=plants;
class type block;
model stemleng = type block / selection=none stb showpvalues;
run;
The design matrix can be saved in a data set by adding the OUTDESIGN= option.
proc glmselect data=plants noprint outdesign=design;
class type block;
model stemleng = type block / selection=none;
run;
proc print data=design(obs=5) noobs;
id stemleng; var type: block:;
run;
The first five observations in the OUTDESIGN= data set are shown below. Note that each of the design variable names begins with type or block. You can then specify type: to list all of the TYPE design variables and similarly for the BLOCK variables as shown in the VAR statement above.
The model can now be fit in PROC REG by specifying the design variables. The STB option provides the standardized estimates.
title 'REG: unstandardized and standardized estimates';
ods select ParameterEstimates;
proc reg data=design;
model stemleng = type: block: / stb;
run; quit;
In the following PROC STANDARD step, the M=0 and S=1 options standardize each of the design variables to have zero mean and unit standard deviation. PROC GLM can then fit the model using the standardized data to produce standardized estimates. The CLPARM option in the MODEL statement produces confidence limits on the standardized estimates.
proc standard data=design out=new mean=0 std=1;
run;
title 'GLM: standardized estimates and confidence limits';
ods select ParameterEstimates;
proc glm data=new;
model stemleng = type: block: / clparm;
run; quit;
Similarly, you can use PROC REG with the CLB option in the MODEL statement to obtain the same standardized estimates and confidence limits (results not shown).
title 'REG: standardized estimates and confidence limits';
ods select ParameterEstimates;
proc reg data=new;
model stemleng = type: block: / clb;
run; quit;
Operating System and Release Information
| Product Family | Product | System | SAS Release | |
| Reported | Fixed* | |||
| SAS System | SAS/STAT | All | n/a | |
| Type: | Usage Note |
| Priority: | low |
| Topic: | SAS Reference ==> Procedures ==> REG Analytics ==> Regression SAS Reference ==> Procedures ==> GLM SAS Reference ==> Procedures ==> GLMMOD SAS Reference ==> Procedures ==> GLIMMIX SAS Reference ==> Procedures ==> GLMSELECT SAS Reference ==> Procedures ==> STANDARD |
| Date Modified: | 2026-07-24 13:05:38 |
| Date Created: | 2002-12-16 10:56:38 |