When the TREND option is specified in the STRATA statement, PROC LIFETEST displays p-values for two-sided trend tests in the column labeled Pr > |z| in the Trend Tests table. Beginning in SAS 9.2, the lower one-sided p-value, Pr < z, and the upper one-sided p-value, Pr > z for ordered alternatives are also displayed.

The null hypothesis for these tests is H₀: S₁(t) = S₂(t) = ... = S_k(t), for all t ≤ τ where τ is some upper bound and k is the number of survival functions being compared.

There are two ordered alternative hypotheses for the trend test:

H₁: S₁(t) ≥ S₂(t) ≥ ... ≥ S_k(t)

H₂: S₁(t) ≤ S₂(t) ≤ ... ≤ S_k(t)

for all t ≤ τ and with at least one inequality in each hypothesis, as shown in "Computational Formulas: Trend Tests" in the Details section of the LIFETEST documentation.

If you are not sure which of the two ordered alternatives are to be considered then a two-sided test is appropriate. Collett (2003, pg. 53) illustrates reporting a two-sided p-value for the trend test.

Tests for the ordered alternatives (H₁ or H₂ above) are provided automatically by the TREND option beginning in SAS 9.2. Prior to that release, p-values for these tests can be computed as discussed below.

Upper one-sided test of the H₁ alternative

The p-value for this test is obtained using either of the following. A small p-value indicates significance and rejects the null in favor of this ordered alternative.

• In a subsequent DATA step, compute p_value = 1-PROBNORM(z); where z is the value in the "Test Statistic" column of the Trend Tests table,

  or

• Compute p-value = p/2 if z ≥ 0 or 1-(p/2) if z < 0, where p is the Pr > |z| two-sided p-value displayed in the Trend Tests table and z is as above.

Lower one-sided test of the H₂ alternative

The p-value for this test is obtained using either of the following. A small p-value indicates significance and rejects the null in favor of this ordered alternative.

• In a subsequent DATA step, compute p_value = PROBNORM(z); where z is the value in the "Test Statistic" column of the Trend Tests table,

  or

• Compute p-value = p/2 if z ≤ 0 or 1-(p/2) if z > 0, where p is the Pr > |z| two-sided p-value displayed in the Trend Tests table and z is as above.

__________

References

Collett (2003)

Klein and Moeschberger (2003)

Operating System and Release Information

Product Family	Product	System	SAS Release
			Reported	Fixed*
SAS System	SAS/STAT	Microsoft Windows 8 Pro 32-bit
		z/OS
		Z64
		OpenVMS VAX
		Microsoft® Windows® for 64-Bit Itanium-based Systems
		Microsoft Windows Server 2003 Datacenter 64-bit Edition
		Microsoft Windows Server 2003 Enterprise 64-bit Edition
		Microsoft Windows XP 64-bit Edition
		Microsoft® Windows® for x64
		OS/2
		Microsoft Windows 8 Enterprise 32-bit
		Microsoft Windows 8 Enterprise x64
		Microsoft Windows 8 Pro x64
		Microsoft Windows 95/98
		Microsoft Windows 2000 Advanced Server
		Microsoft Windows 2000 Datacenter Server
		Microsoft Windows 2000 Server
		Microsoft Windows 2000 Professional
		Microsoft Windows NT Workstation
		Microsoft Windows Server 2003 Datacenter Edition
		Microsoft Windows Server 2003 Enterprise Edition
		Microsoft Windows Server 2003 Standard Edition
		Microsoft Windows Server 2003 for x64
		Microsoft Windows Server 2008
		Microsoft Windows Server 2008 R2
		Microsoft Windows Server 2008 for x64
		Microsoft Windows Server 2012 Datacenter
		Microsoft Windows Server 2012 Std
		Microsoft Windows XP Professional
		Windows 7 Enterprise 32 bit
		Windows 7 Enterprise x64
		Windows 7 Home Premium 32 bit
		Windows 7 Home Premium x64
		Windows 7 Professional 32 bit
		Windows 7 Professional x64
		Windows 7 Ultimate 32 bit
		Windows 7 Ultimate x64
		Windows Millennium Edition (Me)
		Windows Vista
		Windows Vista for x64
		64-bit Enabled AIX
		64-bit Enabled HP-UX
		64-bit Enabled Solaris
		ABI+ for Intel Architecture
		AIX
		HP-UX
		HP-UX IPF
		IRIX
		Linux
		Linux for x64
		Linux on Itanium
		OpenVMS Alpha
		OpenVMS on HP Integrity
		Solaris
		Solaris for x64
		Tru64 UNIX

* For software releases that are not yet generally available, the Fixed Release is the software release in which the problem is planned to be fixed.

The TREND option on the STRATA statement first became available in SAS9.1 and PROC LIFETEST displayed two-sided p-values for the trend tests. Beginning in SAS9.2 the lower and upper one-sided p-values are also displayed. The code below illustrates several strata homogeneity tests via the TEST=(logrank Wilcoxon Tarone Peto ModPeto Fleming(1,0)) option and the trend tests from the TREND option. We find it more convenient to view the output to use two PROC LIFETEST steps - one for the HomTests ODS table (strata homogeneity tests) and another for the TrendScores and TrendTests ODS tables. We also output the TrendTests results using ODS OUTPUT and print them with PROC PRINT.

---

/*****************/
/* survival data */
/*****************/
 data VALung;
      drop check m;
      retain Therapy Cell;
      infile cards column=column;
      length Check $ 1;
      label SurvTime='failure or censoring time'
         Kps='karnofsky index'
         DiagTime='months till randomization'
         Age='age in years'
         Prior='prior treatment?'
         Cell='cell type'
         Therapy='type of treatment'
         Treatment='treatment indicator';
      M=Column;
      input Check $ @@;
      if M>Column then M=1;
      if Check='s'|Check='t' then input @M Therapy $ Cell $ ;
      else input @M SurvTime Kps DiagTime Age Prior @@;
      if SurvTime > .;
      censor=(SurvTime<0);
      SurvTime=abs(SurvTime);
      Treatment=(Therapy='test');
      cards;
   standard squamous
    72 60  7 69  0   411 70  5 64 10   228 60  3 38  0   126 60  9 63 10
   118 70 11 65 10    10 20  5 49  0    82 40 10 69 10   110 80 29 68  0
   314 50 18 43  0  -100 70  6 70  0    42 60  4 81  0     8 40 58 63 10
   144 30  4 63  0   -25 80  9 52 10    11 70 11 48 10
   standard small
    30 60  3 61  0   384 60  9 42  0     4 40  2 35  0    54 80  4 63 10
    13 60  4 56  0  -123 40  3 55  0   -97 60  5 67  0   153 60 14 63 10
    59 30  2 65  0   117 80  3 46  0    16 30  4 53 10   151 50 12 69  0
    22 60  4 68  0    56 80 12 43 10    21 40  2 55 10    18 20 15 42  0
   139 80  2 64  0    20 30  5 65  0    31 75  3 65  0    52 70  2 55  0
   287 60 25 66 10    18 30  4 60  0    51 60  1 67  0   122 80 28 53  0
    27 60  8 62  0    54 70  1 67  0     7 50  7 72  0    63 50 11 48  0
   392 40  4 68  0    10 40 23 67 10
   standard adeno
     8 20 19 61 10    92 70 10 60  0    35 40  6 62  0   117 80  2 38  0
   132 80  5 50  0    12 50  4 63 10   162 80  5 64  0     3 30  3 43  0
    95 80  4 34  0
   standard large
   177 50 16 66 10   162 80  5 62  0   216 50 15 52  0   553 70  2 47  0
   278 60 12 63  0    12 40 12 68 10   260 80  5 45  0   200 80 12 41 10
   156 70  2 66  0  -182 90  2 62  0   143 90  8 60  0   105 80 11 66  0
   103 80  5 38  0   250 70  8 53 10   100 60 13 37 10
   test squamous
   999 90 12 54 10   112 80  6 60  0   -87 80  3 48  0  -231 50  8 52 10
   242 50  1 70  0   991 70  7 50 10   111 70  3 62  0     1 20 21 65 10
   587 60  3 58  0   389 90  2 62  0    33 30  6 64  0    25 20 36 63  0
   357 70 13 58  0   467 90  2 64  0   201 80 28 52 10     1 50  7 35  0
    30 70 11 63  0    44 60 13 70 10   283 90  2 51  0    15 50 13 40 10
   test small
    25 30  2 69  0  -103 70 22 36 10    21 20  4 71  0    13 30  2 62  0
    87 60  2 60  0     2 40 36 44 10    20 30  9 54 10     7 20 11 66  0
    24 60  8 49  0    99 70  3 72  0     8 80  2 68  0    99 85  4 62  0
    61 70  2 71  0    25 70  2 70  0    95 70  1 61  0    80 50 17 71  0
    51 30 87 59 10    29 40  8 67  0
   test adeno
    24 40  2 60  0    18 40  5 69 10   -83 99  3 57  0    31 80  3 39  0
    51 60  5 62  0    90 60 22 50 10    52 60  3 43  0    73 60  3 70  0
     8 50  5 66  0    36 70  8 61  0    48 10  4 81  0     7 40  4 58  0
   140 70  3 63  0   186 90  3 60  0    84 80  4 62 10    19 50 10 42  0
    45 40  3 69  0    80 40  4 63  0
   test large
    52 60  4 45  0   164 70 15 68 10    19 30  4 39 10    53 60 12 66  0
    15 30  5 63  0    43 60 11 49 10   340 80 10 64 10   133 75  1 65  0
   111 60  5 64  0   231 70 18 67 10   378 80  4 65  0    49 30  3 37  0
   ;


/*********/
/* PRINT */
/*********/
title1 "VALung Cancer Survival Data";
title2 "Censor=1 (censored), Censor=0 (censored)";
proc sort data=VALung;
     by Cell SurvTime Censor;
proc print data=VALung;
     by Cell;
     pageby Cell;
     id Cell;
     var SurvTime Censor;
     run;


/************/
/* LIFETEST */
/************/
ods select HomTests;
proc lifetest data=VALung;
     strata cell / test=(logrank Wilcoxon Tarone Peto ModPeto Fleming(1,0));
     time SurvTime*Censor(1);
     title1 "HomTests test Ho: SDF all equal vs Ha: SDF not all equal";
     title2 "1-sided pvalue is from upper tail of chisquare(df=#strata-1) dist.";
     title3 "Version = &sysver.";
     run;

ods select TrendScores TrendTests;
proc lifetest data=VALung;
     strata cell / test=(logrank Wilcoxon Tarone Peto ModPeto Fleming(1,0)) trend;
     time SurvTime*Censor(1);
     ods output TrendTests=TS;
     title1 "TrendTests table has 2-sided pvalues based on z~N(0,1) dist.";
     title2 "Version = &sysver. (&sysvlong.)";
     run;


/***************************/
/* TrendTests ODS data set */
/***************************/
proc print data=TS;
     format Probz LowerProbz UpperProbz 6.4;
     title1 "TrendTests ODS data set";
     title2 "pvalues displayed here were manually formatted as 6.4";
     title3 "Version = &sysver. (&sysvlong.)";
     run;
quit;

Details of the trend tests produced by the TREND option in the STRATA statement in PROC LIFETEST are discussed.

Type:	Usage Note
Priority:
Topic:	Analytics ==> Survival Analysis SAS Reference ==> Procedures ==> LIFETEST

Date Modified:	2013-10-04 10:19:45
Date Created:	2007-03-27 14:32:44