Example 9 for PROC GLM
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: GLMEX9 */
/* TITLE: Example 9 for PROC GLM */
/* PRODUCT: STAT */
/* SYSTEM: ALL */
/* KEYS: Doubly multivariate repeated measures */
/* PROCS: GLM */
/* DATA: */
/* */
/* SUPPORT: sasrdt */
/* REF: PROC GLM, EXAMPLE 9. */
/* MISC: */
/****************************************************************/
/* Doubly Multivariate Repeated Measures Design Analysis -------*/
options ls=96;
data Trial;
input Treatment $ Repetition PreY1 PostY1 FollowY1
PreY2 PostY2 FollowY2;
datalines;
A 1 3 13 9 0 0 9
A 2 0 14 10 6 6 3
A 3 4 6 17 8 2 6
A 4 7 7 13 7 6 4
A 5 3 12 11 6 12 6
A 6 10 14 8 13 3 8
B 1 9 11 17 8 11 27
B 2 4 16 13 9 3 26
B 3 8 10 9 12 0 18
B 4 5 9 13 3 0 14
B 5 0 15 11 3 0 25
B 6 4 11 14 4 2 9
Control 1 10 12 15 4 3 7
Control 2 2 8 12 8 7 20
Control 3 4 9 10 2 0 10
Control 4 10 8 8 5 8 14
Control 5 11 11 11 1 0 11
Control 6 1 5 15 8 9 10
;
proc glm data=Trial;
class Treatment;
model PreY1 PostY1 FollowY1
PreY2 PostY2 FollowY2 = Treatment / nouni;
repeated Response 2 identity, Time 3;
run;
/* Use MANOVA Statement to Test for Overall Main Effect of Time */
proc glm data=Trial;
class Treatment;
model PreY1 PostY1 FollowY1
PreY2 PostY2 FollowY2 = Treatment / nouni;
manova h=intercept m=prey1 - posty1,
prey1 - followy1,
prey2 - posty2,
prey2 - followy2 / summary;
run;