Documentation Examples for Clustering Introduction
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: INTCLUS */
/* TITLE: Documentation Examples for Clustering Introduction */
/* PRODUCT: SAS */
/* SYSTEM: ALL */
/* KEYS: CLUSTER */
/* PROCS: ACECLUS CLUSTER FASTCLUS PLOT TREE SGPLOT */
/* DATA: */
/* */
/* SUPPORT: saswfk UPDATE: July 25, 2010 */
/* REF: */
/* MISC: */
/* */
/****************************************************************/
data compact;
keep x y;
n=50; scale=1;
mx=0; my=0; link generate;
mx=8; my=0; link generate;
mx=4; my=8; link generate;
stop;
generate:
do i=1 to n;
x=rannor(1)*scale+mx;
y=rannor(1)*scale+my;
output;
end;
return;
run;
proc cluster data=compact outtree=tree method=single noprint;
run;
proc tree noprint out=out n=3;
copy x y;
run;
%modstyle(name=ClusterStyle,parent=Statistical,type=CLM,
markers=Circle Triangle Square circlefilled);
ods listing style=ClusterStyle;
proc sgplot;
scatter y=y x=x / group=cluster;
title 'Single Linkage Cluster Analysis: '
'Well-Separated, Compact Clusters';
run;
data closer;
keep x y c;
n=50; scale=1;
mx=0; my=0; c=3; link generate;
mx=3; my=0; c=1; link generate;
mx=1; my=2; c=2; link generate;
stop;
generate:
do i=1 to n;
x=rannor(9)*scale+mx;
y=rannor(9)*scale+my;
output;
end;
return;
run;
title 'True Clusters for Data Containing Poorly Separated, Compact Clusters';
proc sgplot;
scatter y=y x=x / group=c ;
run;
proc fastclus data=closer out=out maxc=3 noprint;
var x y;
title 'FASTCLUS Analysis: '
'Poorly Separated, Compact Clusters';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
proc cluster data=closer outtree=tree method=ward noprint;
var x y;
run;
proc tree noprint out=out n=3;
copy x y;
title 'Ward''s Minimum Variance Cluster Analysis: '
'Poorly Separated, Compact Clusters';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
proc cluster data=closer outtree=tree method=average noprint;
var x y;
run;
proc tree noprint out=out n=3 dock=5;
copy x y;
title 'Average Linkage Cluster Analysis: '
'Poorly Separated, Compact Clusters';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
proc cluster data=closer outtree=tree method=centroid noprint;
var x y;
run;
proc tree noprint out=out n=3 dock=5;
copy x y;
title 'Centroid Cluster Analysis: '
'Poorly Separated, Compact Clusters';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
proc cluster data=closer outtree=tree method=twostage k=10 noprint;
var x y;
run;
proc tree noprint out=out n=3;
copy x y _dens_;
title 'Two-Stage Density Linkage Cluster Analysis: '
'Poorly Separated, Compact Clusters';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
proc sgplot;
bubble y=y x=x size=_dens_ / nofill lineattrs=graphdatadefault;
title 'Estimated Densities for Data Containing Poorly Separated, '
'Compact Clusters';
run;
proc cluster data=closer outtree=tree method=single noprint;
var x y;
run;
proc tree data=tree noprint out=out n=3 dock=5;
copy x y;
title 'Single Linkage Cluster Analysis: '
'Poorly Separated, Compact Clusters';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
data unequal;
keep x y c;
mx=1; my=0; n=20; scale=.5; c=1; link generate;
mx=6; my=0; n=80; scale=2.; c=3; link generate;
mx=3; my=4; n=40; scale=1.; c=2; link generate;
stop;
generate:
do i=1 to n;
x=rannor(1)*scale+mx;
y=rannor(1)*scale+my;
output;
end;
return;
run;
title 'True Clusters for Data Containing Multinormal Clusters of Unequal Size';
proc sgplot;
scatter y=y x=x / group=c;
run;
proc fastclus data=unequal out=out maxc=3 noprint;
var x y;
title 'FASTCLUS Analysis: Compact Clusters of Unequal Size';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
proc cluster data=unequal outtree=tree method=ward noprint;
var x y;
run;
proc tree noprint out=out n=3;
copy x y;
title 'Ward''s Minimum Variance Cluster Analysis: '
'Compact Clusters of Unequal Size';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
proc cluster data=unequal outtree=tree method=average noprint;
var x y;
run;
proc tree noprint out=out n=3 dock=5;
copy x y;
title 'Average Linkage Cluster Analysis: '
'Compact Clusters of Unequal Size';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
proc cluster data=unequal outtree=tree method=centroid noprint;
var x y;
run;
proc tree noprint out=out n=3 dock=5;
copy x y;
title 'Centroid Cluster Analysis: '
'Compact Clusters of Unequal Size';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
proc cluster data=unequal outtree=tree method=twostage k=10 noprint;
var x y;
run;
proc tree noprint out=out n=3;
copy x y _dens_;
title 'Two-Stage Density Linkage Cluster Analysis: '
'Compact Clusters of Unequal Size';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
proc sgplot;
bubble y=y x=x size=_dens_ / nofill lineattrs=graphdatadefault;
title 'Estimated Densities for Data Containing '
'Compact Clusters of Unequal Size';
run;
proc cluster data=unequal outtree=tree method=single noprint;
var x y;
run;
proc tree data=tree noprint out=out n=3 dock=5;
copy x y;
title 'Single Linkage Cluster Analysis: '
'Compact Clusters of Unequal Size';
run;
proc sgplot;
scatter y=y x=x / group=cluster;
run;
data elongate;
keep x y;
ma=8; mb=0; link generate;
ma=6; mb=8; link generate;
stop;
generate:
do i=1 to 50;
a=rannor(7)*6+ma;
b=rannor(7)+mb;
x=a-b;
y=a+b;
output;
end;
return;
run;
proc fastclus data=elongate out=out maxc=2 noprint;
run;
%modstyle(name=ClusterStyle2,parent=Statistical,type=CLM,
markers=Circle Triangle circlefilled);
ods listing style=ClusterStyle2;
proc sgplot;
scatter y=y x=x / group=cluster;
title 'FASTCLUS Analysis: Parallel Elongated Clusters';
run;
proc cluster data=elongate outtree=tree method=average noprint;
run;
proc tree noprint out=out n=2 dock=5;
copy x y;
run;
proc sgplot;
scatter y=y x=x / group=cluster;
title 'Average Linkage Cluster Analysis: '
'Parallel Elongated Clusters';
run;
proc cluster data=elongate outtree=tree method=twostage k=10 noprint;
run;
proc tree noprint out=out n=2;
copy x y;
run;
proc sgplot;
scatter y=y x=x / group=cluster;
title 'Two-Stage Density Linkage Cluster Analysis: '
'Parallel Elongated Clusters';
run;
proc aceclus data=elongate out=ace p=.1;
var x y;
title 'ACECLUS Analysis: Parallel Elongated Clusters';
run;
proc sgplot;
scatter y=can2 x=can1;
title 'Data Containing Parallel Elongated Clusters';
title2 'After Transformation by PROC ACECLUS';
run;
proc cluster data=ace outtree=tree method=ward noprint;
var can1 can2;
copy x y;
run;
proc tree noprint out=out n=2;
copy x y;
run;
proc sgplot;
scatter y=y x=x / group=cluster;
title 'Ward''s Minimum Variance Cluster Analysis: '
'Parallel Elongated Clusters';
title2 'After Transformation by PROC ACECLUS';
run;
data noncon;
keep x y;
do i=1 to 100;
a=i*.0628319;
x=cos(a)+(i>50)+rannor(7)*.1;
y=sin(a)+(i>50)*.3+rannor(7)*.1;
output;
end;
run;
proc fastclus data=noncon out=out maxc=2 noprint;
run;
proc sgplot;
scatter y=y x=x / group=cluster;
title 'FASTCLUS Analysis: Nonconvex Clusters';
run;
proc cluster data=noncon outtree=tree method=centroid noprint;
run;
proc tree noprint out=out n=2 dock=5;
copy x y;
run;
proc sgplot;
scatter y=y x=x / group=cluster;
title 'Centroid Cluster Analysis: Nonconvex Clusters';
run;
proc cluster data=noncon outtree=tree method=twostage k=10 noprint;
run;
proc tree noprint out=out n=2;
copy x y;
run;
proc sgplot;
scatter y=y x=x / group=cluster;
title 'Two-Stage Density Linkage Cluster Analysis: Nonconvex Clusters';
run;