Documentation Example 8 for PROC MI
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: MIEX8 */
/* TITLE: Documentation Example 8 for PROC MI */
/* PRODUCT: STAT */
/* SYSTEM: ALL */
/* KEYS: multiple imputation */
/* PROCS: MI */
/* DATA: */
/* */
/* SUPPORT: Yang Yuan UPDATE: Aug 21, 2007 */
/* REF: PROC MI, EXAMPLE 8 */
/* MISC: */
/****************************************************************/
*-----------------------------Fish3 Data-----------------------------*
| The data set contains two species of the fish (Bream and Pike) |
| and three measurements: Length, Height, Width. |
| Some values have been set to missing, and the resulting data set |
| has an arbitrary missing pattern. |
*--------------------------------------------------------------------*;
data Fish3;
title 'Fish Measurement Data';
input Species $ Length Height Width @@;
datalines;
Bream 30.0 11.520 4.020 . 31.2 12.480 4.306
Bream 31.1 12.378 4.696 Bream 33.5 12.730 4.456
. . 12.444 . Bream 34.7 13.602 4.927
Bream 34.5 14.180 5.279 . 35.0 . 4.690
Bream 35.1 14.005 4.844 Bream 36.2 14.227 4.959
. 36.2 14.263 . Bream 36.2 14.371 4.815
Bream 36.4 13.759 4.368 Bream 37.3 13.913 5.073
Bream 37.2 14.954 5.171 . 37.2 . 5.580
Bream 38.3 14.860 5.285 Bream 38.5 14.938 5.198
. 38.6 15.633 5.134 Bream 38.7 14.474 5.728
Bream 39.5 15.129 5.570 . 39.2 15.994 .
Bream 39.7 15.523 5.280 Bream 40.6 15.469 6.131
. 40.5 . . Bream 40.9 16.360 6.053
Bream 40.6 16.362 6.090 Bream 41.5 16.517 5.852
Bream 41.6 16.890 6.198 Bream 42.6 18.957 6.603
Bream . 18.037 . Bream . 18.084 6.292
Bream 45.3 18.754 6.750 Bream 45.9 18.635 6.747
Bream 46.5 17.624 6.371
Pike 34.8 5.568 3.376 Pike 37.8 5.708 4.158
Pike 38.8 5.936 4.384 . 39.8 . .
Pike 40.5 7.290 4.577 Pike 41.0 6.396 3.977
. 45.5 7.280 4.323 Pike 45.5 6.825 4.459
Pike 45.8 7.786 5.130 Pike 48.0 6.960 4.896
Pike 48.7 7.792 4.870 Pike 51.2 7.680 5.376
Pike 55.1 8.926 6.171 . 59.7 10.686 .
Pike 64.0 9.600 6.144 Pike 64.0 9.600 6.144
Pike . 10.812 7.480
;
ods graphics on;
proc mi data=Fish3 seed=1305417 out=outex8;
class Species;
fcs plots=trace
logistic(Species= Height Width Height*Width /details);
var Species Height Width;
run;
ods graphics off;
proc print data=outex8(obs=10);
title 'First 10 Observations of the Imputed Data Set';
run;