Resources

Getting Started Example for PROC UCM

/*--------------------------------------------------------------

                    SAS Sample Library

        Name: ucmgs.sas
 Description: Example program from SAS/ETS User's Guide,
              The UCM Procedure
       Title: Getting Started Example for PROC UCM
     Product: SAS/ETS Software
        Keys: equally spaced univariate time series data
        PROC: UCM
       Notes:

--------------------------------------------------------------*/

ods graphics on;

data seriesG;
   set sashelp.air;
   logair = log( air );
run;

proc timeseries data=seriesG plot=series;
   id date interval=month;
   var logair;
run;

proc ucm data=seriesG;
   id date interval=month;
   model logair;
   irregular;
   level;
   slope;
   season length=12 type=trig print=smooth;
   estimate;
   forecast lead=24 print=decomp;
run;

proc ucm data=seriesG;
   id date interval = month;
   model logair;
   irregular;
   level plot=smooth;
   slope variance=0 noest;
   season length=12 type=trig
       plot=smooth;
   estimate;
   forecast lead=24 plot=decomp;
run;