Introduction to Structural Equation Modeling with Latent Variables

Jöreskog and Sörbom (1988) present more detailed results from a second analysis in which two constraints are imposed:

Applying these constraints to Figure 17.40, you get the path diagram displayed in Figure 17.44.

Figure 17.44: Path Diagram for Career Aspiration : Analysis 2

In Figure 17.44, the double-headed path that connected R_Amb and F_Amb no longer exists. Also, the single-headed paths between R_Amb and F_Amb are both labeled with beta, indicating the required constrained effects in the model. The path diagram in Figure 17.44 is transcribed into the PATH model in the following statements:

proc calis data=aspire nobs=329;
   path
      /* structural model of influences */
      rpa    ===> R_Amb         ,
      riq    ===> R_Amb         ,
      rses   ===> R_Amb         ,
      fses   ===> R_Amb         ,
      rses   ===> F_Amb         ,
      fses   ===> F_Amb         ,
      fiq    ===> F_Amb         ,
      fpa    ===> F_Amb         ,
      F_Amb  ===> R_Amb   = beta,
      R_Amb  ===> F_Amb   = beta,

      /* measurement model for aspiration */
      R_Amb  ===> rea         ,
      R_Amb  ===> roa     = 1.,
      F_Amb  ===> foa     = 1.,
      F_Amb  ===> fea     ;
run;

The only differences between the current specification and the preceding specification for Analysis 1 are the labeling of two paths with the same parameter beta and the deletion of PCOV statement where the covariance of R_Amb and F_Amb was specified in Analysis 1. The fit summary of the current model is displayed in Figure 17.45, and the estimation results are displayed in Figure 17.46.

The model fit chi-square value is 26.8987 (df=17, p=0.0596). The standardized RMSR and the RMSEA are both less than 0.05, while the adjusted GFI and comparative fit index are both bigger than 0.9. All these indicate a good model fit, but how does this model (Analysis 2) compare with that in Analysis 1?

The difference between the chi-square values for Analyses 1 and 2 is with two degrees of freedom, which is far from significant. This indicates that the restricted model (Analysis 2) fits as well as the unrestricted model (Analysis 1). The AIC is 102.8987, and the SBC is 247.149. Both of these values are smaller than that of Analysis 1 (106.697 for AIC and 258.540 for SBC), and hence they indicate that the current model is a better one.

Like Analysis 1, the same two paths in the current analysis are not significant. That is, fses does not seem to be a good indicator of a respondent’s ambition R_Amb, and rses does not seem to be a good indicator of a friend’s ambition F_Amb. The t values are 1.862 and 1.768, respectively.