The FACTEX Procedure

Note: See Replicated Blocked Design with Confounding in the SAS/QC Sample Library.

In an unreplicated blocked design, the interaction effect that is confounded with the block effect cannot be estimated. You can replicate the experiment so that a different interaction effect is confounded in each replicate. This enables you to obtain information about an interaction effect from the replicates in which it is not confounded.

For example, consider a design with factors A, B, and C arranged in two blocks. Suppose you decide to run four replicates of the design. By constructing the design sequentially, you can choose the effects to be estimated in each replicate depending on the interaction confounded with the block effect in the other replicates.

In the first replicate, you specify only that the main effects are to be estimable. The following statements generate an eight-run two-level design arranged in two blocks:

proc factex;
   factors A B C;
   blocks nblocks=2;
   model est=(A B C);
   examine confounding aliasing;
   output out=Rep1 blockname=block nvals=(1 2);
run;

The alias structure and the confounding scheme are listed in Output 7.12.1. The highest-order interaction A*B*C is confounded with the block effect. The design, with recoded block levels, is saved in a data set named REP1.

If you were to analyze this replicate by itself, you could not determine whether an effect is due to A*B*C or the block effect. You can construct a second replicate that confounds a different interaction effect with the block effect. Since the FACTEX procedure is interactive, simply submit the following statements to generate the second replicate:

   model est=(A B C A*B*C);
   output out=Rep2
      blockname=block nvals=(3 4);
run;

The alias structure and the confounding scheme for the second replicate are listed in Output 7.12.2. The interaction A*B*C is free of any aliases, but now the two-factor interaction B*C is confounded with the block effect.

To estimate the interaction B*C with the third replicate, submit the following statements (immediately after the preceding statements):

   model est=(A B C A*B*C B*C);
   output out=Rep3 blockname=block nvals=(5 6);
run;

The alias structure and confounding rules are shown in Output 7.12.3. The interaction B*C is free of aliases, but the interaction A*C is confounded with the block effect.

Finally, to estimate the interaction effect A*C with the fourth replicate, submit the following statements:

   model est=(A B C A*B*C B*C A*C);
   output out=Rep4 blockname=block nvals=(7 8);
run;

The alias structure and confounding rules are displayed in Output 7.12.4.

When combined, these four replicates give full information on the main effects and three-quarter information on each of the interactions. The following statements combine the four replicates:

data Combine;
   set Rep1 Rep2 Rep3 Rep4;
run;
proc print data=Combine;
run;

The final design is saved in the data set Combine. A listing of this data set is shown in Output 7.12.5.