High-performance analytical procedures use the following rules to determine whether they run in single-machine mode or distributed mode:

The following example shows single-machine and client-data distributed configurations for a data set of 100,000 observations that are simulated from a logistic regression model. The following DATA step generates the data:

 
data simData; 
   array _a{8} _temporary_ (0,0,0,1,0,1,1,1); 
   array _b{8} _temporary_ (0,0,1,0,1,0,1,1); 
   array _c{8} _temporary_ (0,1,0,0,1,1,0,1); 
   do obsno=1 to 100000; 
      x  = rantbl(1,0.28,0.18,0.14,0.14,0.03,0.09,0.08,0.06); 
      a  = _a{x}; 
      b  = _b{x}; 
      c  = _c{x}; 
      x1 = int(ranuni(1)*400); 
      x2 = 52 + ranuni(1)*38; 
      x3 = ranuni(1)*12; 
      lp = 6. -0.015*(1-a) + 0.7*(1-b) + 0.6*(1-c) + 0.02*x1 -0.05*x2 - 0.1*x3; 
      y  = ranbin(1,1,(1/(1+exp(lp)))); 
      output; 
   end; 
   drop x lp; 
run; 

The following statements run PROC HPLOGISTIC to fit a logistic regression model:

 
proc hplogistic data=simData; 
   class a b c; 
   model y = a b c x1 x2 x3; 
run; 

Figure 2.1 shows the results from the analysis.

The entries in the “Performance Information” table show that the HPLOGISTIC procedure runs in single-machine mode and uses four threads, which are chosen according to the number of CPUs on the client machine. You can force a certain number of threads on any machine that is involved in the computations by specifying the NTHREADS option in the PERFORMANCE statement. Another indication of execution on the client is the following message, which is issued in the SAS log by all high-performance analytical procedures:

 
NOTE: The HPLOGISTIC procedure is executing on the client.

The following statements use 10 nodes (in distributed mode) to analyze the data on the appliance; results appear in Figure 2.2:

 
proc hplogistic data=simData; 
   class a b c; 
   model y = a b c x1 x2 x3; 
   performance host="hpa.sas.com" nodes=10; 
run; 

The specification of a host causes the “Performance Information” table to display the name of the host node of the appliance. The “Performance Information” table also indicates that the calculations were performed in a distributed environment on the appliance. Twenty-four threads on each of 10 nodes were used to perform the calculations—for a total of 240 threads.

Another indication of distributed execution on the appliance is the following message, which is issued in the SAS log by all high-performance analytical procedures:

 
NOTE: The HPLOGISTIC procedure is executing in the distributed 
      computing environment with 10 worker nodes. 

You can override the presence of a grid host and force the computations into single-machine mode by specifying the NODES=0 option in the PERFORMANCE statement:

 
proc hplogistic data=simData; 
   class a b c; 
   model y = a b c x1 x2 x3; 
   performance host="hpa.sas.com" nodes=0;   
run; 

Figure 2.3 shows the “Performance Information” table. The numeric results are not reproduced here, but they agree with the previous analyses, which are shown in Figure 2.1 and Figure 2.2.

The “Performance Information” table indicates that the HPLOGISTIC procedure executes in single-machine mode on the client. This information is also reported in the following message, which is issued in the SAS log:

 
NOTE: The HPLOGISTIC procedure is executing on the client.

In the analysis shown previously in Figure 2.2, the data set Work.simData is local to the client, and the HPLOGISTIC procedure distributed the data to 10 nodes on the appliance. The High-Performance Analytics infrastructure does not keep these data on the appliance. When the procedure terminates, the in-memory representation of the input data on the appliance is freed.

When the input data set is large, the time that is spent sending client-side data to the appliance might dominate the execution time. In practice, transfer speeds are usually lower than the theoretical limits of the network connection or disk I/O rates. At a transfer rate of 40 megabytes per second, sending a 10-gigabyte data set to the appliance requires more than four minutes. If analytic execution time is in the range of seconds, the “performance” of the process is dominated by data movement.

The alongside-the-database execution model, unique to high-performance analytical procedures, enables you to read and write data in distributed form from the database that is installed on the appliance.