Customized HTML Output

options nodate nonumber;
proc sort data=sashelp.prdsale out=prdsale;
    by Country;
run;
ods html path='your-directory-path' 
        body='bodyPrdsale.htm'
        contents='contentsPrdsale.htm'
        frame='framePrdsale.htm'
        style=Science;
title 'Actual Product Sales';
title2 '(millions of dollars)';

proc tabulate data=prdsale style=[fontweight=bold];   
    class region division prodtype / style=[textalign=center];   
    classlev region division prodtype / style=[textalign=left];   
    var actual / style=[fontsize=3];   
    keyword all sum;
    keylabel all='Total';   
    table (region all)*(division all*[style=[backgroundcolor=yellow]]),
         (prodtype all)*(actual*f=dollar10.) /
         style=[bordercolor=blue]
         misstext=[label='Missing' style=[fontweight=light]]         
         box=[label='Region by Division and Type'
         style=[fontstyle=italic]];   
 run;

ods select ExtremeObs Quantiles Moments;
title "PROC UNIVARIATE Output";
title2;

proc univariate data=prdsale;
    by Country;
    var actual;
run;

title 'Sales Figures for First Quarter by Product';
proc sgpanel data=prdsale;
    where quarter=1;
    panelby product / novarname;
    vbar region / response=predict;
    vline region / response=actual lineattrs=GraphFit;
    colaxis fitpolicy=thin;
    rowaxis label='Sales';
run;
ods html close;