DINFO Function

Returns information about a directory.

Category:	External Files
See:	DINFO Function: Windows in SAS Companion for Windows
	DINFO Function: UNIX in SAS Companion for UNIX Environments
	DINFO Function: z/OS in SAS Companion for z/OS

Syntax

DINFO(directory-id,info-item)

Required Arguments

directory-id

is a numeric variable that specifies the identifier that was assigned when the directory was opened by the DOPEN function.

info-item

is a character constant, variable, or expression that specifies the information item to be retrieved. DINFO returns a blank if the value of the info-item argument is invalid. The information available varies according to the operating environment.

Details

Use the DOPTNAME function to determine the names of the available system-dependent directory information items. Use the DOPTNUM function to determine the number of directory information items that are available.

Operating Environment Information: DINFO returns the value of a system-dependent directory parameter. See the SAS documentation for your operating environment for information about system-dependent directory parameters.

Examples

Example 1: Using DINFO to Return Information about a Directory

This example opens the directory MYDIR, determines the number of directory information items available, and retrieves the value of the last one:

%let filrf=MYDIR;
%let rc=%sysfunc(filename(filrf,physical-name));
%let did=%sysfunc(dopen(&filrf));
%let numopts=%sysfunc(doptnum(&did));
%let foption=%sysfunc(doptname(&did,&numopts));
%let charval=%sysfunc(dinfo(&did,&foption));
%let rc=%sysfunc(dclose(&did));

Example 2: Using DINFO within a DATA Step

This example creates a data set that contains the name and value of each directory information item:

data diropts;
   length foption $ 12 charval $ 40;
   keep foption charval;
   rc=filename("mydir","physical-name");
   did=dopen("mydir");
   numopts=doptnum(did);
   do i=1 to numopts;
      foption=doptname(did,i);
      charval=dinfo(did,foption);
      output;
   end;
run;