NOTALNUM Function

Searches a character string for a non-alphanumeric character, and returns the first position at which the character is found.

Category:	Character
Restriction:	I18N Level 2 functions are designed for use with SBCS, DBCS, and MBCS (UTF8).

Syntax

NOTALNUM(string <,start> )

Required Argument

string

specifies a character constant, variable, or expression to search.

Optional Argument

start

is an optional numeric constant, variable, or expression with an integer value that specifies the position at which the search should start and the direction in which to search.

Details

The results of the NOTALNUM function depend directly on the translation table that is in effect (see TRANTAB= System Option in SAS National Language Support (NLS): Reference Guide) and indirectly on the ENCODING and the LOCALE system options.

The NOTALNUM function searches a string for the first occurrence of any character that is not a digit or an uppercase or lowercase letter. If such a character is found, NOTALNUM returns the position in the string of that character. If no such character is found, NOTALNUM returns a value of 0.

If you use only one argument, NOTALNUM begins the search at the beginning of the string. If you use two arguments, the absolute value of the second argument, start, specifies the position at which to begin the search. The direction in which to search is determined in the following way:

If the value of start is positive, the search proceeds to the right.
If the value of start is negative, the search proceeds to the left.
If the value of start is less than the negative length of the string, the search begins at the end of the string.

NOTALNUM returns a value of zero when one of the following is true:

The character that you are searching for is not found.
The value of start is greater than the length of the string.
The value of start = 0.

Comparisons

The NOTALNUM function searches a character string for a non-alphanumeric character. The ANYALNUM function searches a character string for an alphanumeric character.

Example

The following example uses the NOTALNUM function to search a string from left to right for non-alphanumeric characters.

data _null_;
   string='Next = Last + 1;';
   j=0;
   do until(j=0);
      j=notalnum(string,j+1);
      if j=0 then put +3 "That's all";
      else do;
         c=substr(string,j,1);
         put +3 j= c=;
      end;
   end;
run;

The following lines are written to the SAS log:

   j=5 c= 
   j=6 c==
   j=7 c= 
   j=12 c= 
   j=13 c=+
   j=14 c= 
   j=16 c=;
   That's all