Working within Your SAS Session

filename mymail email "JBrown"
         subject="My SASV9.CFG file"
         attach="c:\sas\sasV9.cfg";
data _null_;
   file mymail;
   put 'Jim,';
   put 'This is my SAS configuration file.';
   put 'I think you might like the';
   put 'new options I added.';
run;

filename outbox email "Ron B";
data _null_;
   file outbox
   /* Overrides value in */ 
   /* filename statement */
   to=("Ron B" "Lisa D")
   cc=("Margaret Z" "Lenny P")
   subject="My SAS output"
   attach="c:\sas\results.out"
   ;
   put 'Folks,';
   put 'Attached is my output from the SAS';
   put 'program I ran last night.'; 
   put 'It worked great!';
run;

filename reports email "Jim";
data _null_;
   file reports;
   length name dept $ 21;
   input name dept;
   /* Assign the TO attribute */
   put '!EM_TO!' name;  
   /* Assign the SUBJECT attribute */
   put '!EM_SUBJECT! Report for ' dept; 
   put name ',';
   put 'Here is the latest report for ' dept '.';
   if dept='marketing' then
      put '!EM_ATTACH! c:\mktrept.txt';
   else  /* ATTACH the appropriate report */
      put '!EM_ATTACH! c:\devrept.txt';

    /* Send the message. */
    put '!EM_SEND!'; 
    /* Clear the message attributes.*/
    put '!EM_NEWMSG!'; 
    /* Abort the message before the */
    /* RUN statement causes it to   */
    /* be sent again.               */
    put '!EM_ABORT!';  
    datalines;
Susan          marketing
Jim            marketing
Rita           development
Herb           development
;
run;

send:
   /* set up a fileref */
   rc = filename('mailit','userid','email');
   /* if the fileref was successfully set up, 
      open the file to write to */
   if rc = 0 then do;
      fid = fopen('mailit','o');
      if fid > 0 then do;
       /* fput statements are used to
          implement writing the mail and 
          the components such as subject,
          who to mail to, etc. */
   fputrc1= fput(fid,line1);
   rc = fwrite(fid);
   fputrc2= fput(fid,'!EM_TO! '||mailto);
   rc = fwrite(fid);
   fputrc3= fput(fid,'!EM_CC! '||copyto);
   rc = fwrite(fid);
   fputrc4= fput(fid,'!EM_ATTACH! '||attach);
   rc = fwrite(fid);
   fputrc5= fput(fid,'!EM_SUBJECT! '||subject);
   rc = fwrite(fid);
   closerc= fclose(fid);
      end;
   end;
return;
cancel:
   call execcmd('end');
return;