The GANNO Procedure

Example 2: Storing Annotate Graphics

Procedure features:

PROC GANNO statement options:

	DESCRIPTION=
	GOUT=
	NAME=

Sample library member:

GANSQUAR

Four Squares

[Four Squares]

This example creates an Annotate data set that draws four colored squares, displays the data set as a single graphics output, and stores the output as a catalog entry in a permanent catalog. In this example, the NAME= option specifies a text string that identifies the name that is stored with the graphics output in the catalog.

goptions reset=all border;

data squares;
   length function style color $ 8 text $ 15;
   xsys="3"; ysys="3";

   color="green";
   function="move"; x=10; y=65; output;
   function="bar";  x=30; y=95; style="solid"; output;

   function="label"; x=10; y=63; position="6";
      style="swissb"; size=2; text="Green"; output;

   color="red";
   function="move"; x=60; y=65; output;
   function="bar";  x=80; y=95; output;
   function="label"; x=60; y=63; position="6";
      style="swissb"; size=2; text="Red"; output;

   color="blue";
   function="move"; x=10; y=15; output;
   function="bar";  x=30; y=45; output;
   function="label"; x=10; y=12; position="6";
      style="swissb"; size=2; text="Blue"; output;

   color="gray";
   function="move"; x=60; y=15; output;
   function="bar";  x=80; y=45; output;
   function="label"; x=60; y=12; position="6";
      style="swissb"; size=2; text="Gray"; output;

   x=88; y=5; position="5"; size=1.5; style="swiss";
      text="GANSQUAR"; output;

   function="frame"; color="red"; when="b";
      style="empty"; output;
run;

proc ganno annotate=squares
   gout=excat
   name="GANSQUAR"
   description="Four squares";
run;
quit;

Top of Page