%MM_Countreg_Create_Scorecode Autocall Macro

%let MyProj = C:\Users\myID;
%let MyProj = C:\Users\minlam\Documents\Projects;
libname CntReg "&MyProj.\CountReg\Test";
options fmtsearch = (CntReg.formats);
proc format library = CntReg cntlout = phf_fmt;
   value $ Gender_fmt
   'Male' = 'Man'
   'Female' = 'Woman';
   value HO_fmt
   0 = 'No'
   1 = 'Yes';
run;
  
data CntReg.phf;
   length CarType $ 5;
   label CarType = 'Type of Car';
   length Gender $ 6;
   format Gender $ Gender_fmt.;
   label Gender = 'Gender Identification';
  
   /* This variable name will test how the macro will resolve name conflicts */
   length Estimate $ 6;
   label Estimate = 'Gender Identification (Copy)';
   label AgeDriver = 'Driver Age';
   format HomeOwner HO_fmt.;
   call streaminit(27513);
  
   do PolicyId = 00001 to 99999;
     StartYr = 2000 + 
               rand('table', 0.1, 0.1, 0.1, 0.1, 0.1, 0.1, 0.1, 0.1, 0.1, 0.1);
       do ExpYr = StartYr to 2011;
          EExp = rand('uniform');
          MyOffset = 0;
          select (rand('table', 0.499, 0.299, 0.199, 0.003));
             when (1)
             do;
                CarType = 'SEDAN';
                fCarType = 0;
             end;
             when (2)
             do;
                CarType = 'TRUCK';
                fCarType = 0.5;
             end;
             when (3)
             do;
                CarType = 'SPORT';
                fCarType = 1.0;
             end;
             otherwise CarType = ' ';
       end;
  
     AgeDriver = 18 + rand('binomial',0.375, 72);
     fAgeDriver = 0.0123 * (AgeDriver - 17);
  
     HomeOwner = rand('bernoulli', 0.25);
     if (HomeOwner eq 0) then fHomeOwner = 0.7;
        else if (HomeOwner eq 1) then fHomeOwner = 0;
     if (HomeOwner eq 1) then
        do;
           IS = round(rand('uniform') * 5) - 2.5;
           fIS = -0.0456 * IS * IS;
        end;     
     if (EExp lt 0.5) then
        do;
           Gender = 'Male';
           fGender = 0;
        end;
        else if (EExp lt 0.9) then
           do;
              Gender = 'Female';
              fGender = -1.5;
           end;
               else Gender = ' ';
     Estimate = Gender;
     if (missing(HomeOwner) eq 0 and missing(IS) eq 0) 
        then mu_zero = 0.987 + fHomeOwner + fIS;
        else mu_zero = 0.987;
     phi = cdf('normal', mu_zero, 0, 1);
     if (rand('bernoulli', phi) eq 0) then
       do;
         if (missing(CarType) eq 0 and missing(AgeDriver) eq 0 and 
             missing(Gender) eq 0) 
            then mu = 2 + fCarType + fAgeDriver + fGender;
            else mu = 2;
         nClaim = rand('poisson', exp(mu));
       end;
       else nClaim = 0;
     output;
   end;
   end;
   drop fCarType fAgeDriver fHomeOwner fGender;
   drop mu_zero mu;
run;

%let MyProj = C:\Users\emdev;
libname CntReg "&MyProj.\CountReg\Test";
options fmtsearch = (CntReg.formats);
   
/* Original Model */
%let model = 1;
   
/* Build the model and deliver the required ODS datasets */
ods output ParameterEstimates = CntReg.ParameterEstimates_&model.;
   
proc countreg data = CntReg.phf;
   class CarType Gender HomeOwner;
   model nClaim = CarType AgeDriver Gender / dist = poisson;
   zeromodel nClaim ~ HomeOwner IS * IS / link = normal;
   output out = CntReg.phf_pred_&model. 
   predicted = Pred_nClaim probzero = Phi_nClaim;
run;
   
ods output close;
  
  
/* Define the fileref for the output syntax */
filename ThisFile "&MyProj.\CountReg\Test\ScoreCode_&Model..sas";
   
/* Invoke the macro */
%mm_countreg_create_scorecode(
   ParamEst = CntReg.ParameterEstimates_&Model.,
   FileRef = ThisFile,
   PredPrefix = MyPred_,
   PZPrefix = MyPhi_,
);
   
/* Execute the score codes within a DATA STEP */
data CntReg.phf_pred_compare;
   set CntReg.phf_pred_&Model.;
   %include ThisFile;
   IsMiss_Pred_nClaim = missing(Pred_nClaim);
   IsMiss_Phi_nClaim = missing(Phi_nClaim);
   IsMiss_MyPred_nClaim = missing(MyPred_nClaim);
   IsMiss_MyPhi_nClaim = missing(MyPhi_nClaim);
   if (IsMiss_Pred_nClaim eq 0 and IsMiss_MyPred_nClaim eq 0) 
     then MyDiffPred = MyPred_nClaim - Pred_nClaim;
   if (IsMiss_Phi_nClaim eq 0 and IsMiss_MyPhi_nClaim eq 0) 
     then MyDiffPhi = MyPhi_nClaim - Phi_nClaim;
run;
   
proc contents data = CntReg.phf_pred_compare;
run;
   
/* If the score codes work correctly, then the MyDifference variable should be 
   a constant variable of all zero values */
proc freq data = CntReg.phf_pred_compare;
   tables _WARN_;
run;
   
proc tabulate data = CntReg.phf_pred_compare;
   class IsMiss_Pred_nClaim IsMiss_MyPred_nClaim 
   IsMiss_Phi_nClaim IsMiss_MyPhi_nClaim;
   var Pred_nClaim MyPred_nClaim MyDiffPred Phi_nClaim 
       MyPhi_nClaim MyDiffPhi;
   table IsMiss_Pred_nClaim * IsMiss_MyPred_nClaim * 
         (n nmiss mean*f=e22. stddev*f=e22. min*f=e22. max*f=e22.), 
         (Pred_nClaim MyPred_nClaim MyDiffPred);
   table IsMiss_Phi_nClaim * IsMiss_MyPhi_nClaim * 
         (n nmiss mean*f=e22. stddev*f=e22. min*f=e22. max*f=e22.), 
         (Phi_nClaim MyPhi_nClaim MyDiffPhi);  
run;
quit;