The following instructions enable you to create dynamic parameter values for a SAS^® Stored Process.

When defining a SAS Stored Process in SAS^® Management Console, you can define parameters for the SAS Stored Process, but any parameter values must be static values.

The example in this SAS Note illustrates an approach for creating dynamically–generated parameter values for a SAS Stored Process. This approach can also be used to dynamically create essentially any HTML page as a front end for submitting a request to a SAS Stored Process.

Another related example is available at Chaining Stored Processes.

Here are some notes:

1. When the SAS Stored Process is initially executed by a user, it returns the HTML page that is used for submitting requests to the same SAS Stored Process on subsequent requests. So, the SAS Stored Process provides its own dynamically–created user interface.
2. This example must use the SAS Stored Process Web application.

   However, you can execute this SAS Stored Process using SAS^® Enterprise Guide^® or the SAS^® Add–In for Microsoft Office (for example) if you do the following:

   1. Modify the SAS^® code and hard code the values for "thissrv" (fully qualified path) and "thispgm".
   2. The first request will be executed using the client (for example, SAS Enterprise Guide). But, the second request will be executed using the SAS Stored Process Web application.

      /**************************************************
        This SAS Stored Process provides an example of creating an
        HTML page with dynamically-generated parameter values.
        This HTML page is then used to submit a request to the
        stored process using the parameter value that was selected.
       **************************************************/
      
      %macro main;
      
       %global reqtype;
      
       %macro first_request;  /* Initial request for user */
      
         /* Get age groups */
       proc summary data=sashelp.class;
         class age;
         output out=summary;
       run;
      
       data _null_;
        set summary end=alldone;
        file _webout;
        if _n_ = 1 then do;
           thissrv = symget('_url');
           thispgm = symget('_program');
           put '<br>';
           put '<h2>Example of dynamicaly-generated parameter values</h2>';
           put '<FORM ACTION="'  thissrv +(-1) '" method=get>';
           put '<input type="hidden" name="_program" value="'
                thispgm +(-1) '">';
           put '<input type="hidden" name=reqtype value="report">';
           put '<br>';
           put '<b>Select Age: </b>';
           put '<select name="age">';
        end;
        if age ne . then do;
             put '<OPTION VALUE="' age '">' age;
        end;
        if alldone then do;
          put '</select>';
          put '<br><br>';
          put '<input type="submit" value="Submit Request">';
          put '</form>';
          put '</html>';
        end;
      
       run;
      
       %mend first_request;
      
       %macro report;  /*  Produce report for user */
      
        %stpbegin;
      
        Title "Students who are age &age";
        proc print data = sashelp.class noobs;
          where age = &age;
          var name age sex;
        run;
      
        %stpend;
      
       %mend report;
      
       %if "&reqtype" = "report" %then %do;
          %report;   /* Produce a report   */
       %end;
       %else %do;
            /* Produce HTML page with parameter values for selection */
          %first_request;
       %end;
      
      %mend main;
      
      %main;
      

Operating System and Release Information