TS-499

WHEN I REPLAY THREE GRAPHS INTO A TEMPLATE, THEY APPEAR DISTORTED. HOW CAN I CORRECT THIS DISTORTION?

Question:

When I replay three graphs into a template, they appear distorted. How can I correct the distortion?

Answer:

The graphs appear distorted because they were created with proportions based on the entire graphics area. These same proportions probably aren't appropriate for the dimensions of the template panels, which may be a different shape. If, when creating the graphs, you adjust the HSIZE and VSIZE values to reflect the dimensions of the template panel, then distortion in the templated graph can be avoided.

The following sample program demonstrates the problem and one solution. First, we create three graphs using the GCHART procedure. When we replay the graphs into the V3 template that is provided in the catalog SASHELP.TEMPLT, we see the distortion you noted:

goptions target=ps hby=0
         ftext=swiss nodisplay;

data one;

   input @1 player $10. @12 rank @14 position $;
   cards;
TAYLOR     1 LB
LAMBERT    2 LB
SINGLETARY 3 LB
SMITH      1 RB
BETTIS     2 RB
SANDERS    3 RB
RICE       1 WR
SHARPE     2 WR
RISON      3 WR
;

proc gchart data=one gout=work.gseg;

   vbar player / sumvar=rank;

   by position;

   title1 'This is a graph for #byval(position)';
   pattern1 v=solid c=black;
 run;
 quit;

goptions display;

proc greplay nofs igout=work.gseg tc=sashelp.templt
               template=v3;

   treplay 1:GCHART
           2:GCHART1
           3:GCHART2;
 run;
 quit;

goptions device=ps nodisplay;

proc gtestit;
 run;
 quit;

   D=PS       B=1200    R= 81 C= 75 P=256
   H= 37 W= 30 MAX=*** D=FFFFFFFFFFF00000
   RF=8000800000000000 S=0000000000000000
   OPTS=FD923040A0000000 NCOLORS=  8
   Background color = WHITE
   Color 1 = BLACK
   Color 2 = GRAY22
   Color 3 = GRAY33
   Color 4 = GRAY44
   Color 5 = GRAY66
   Color 6 = GRAY88
   Color 7 = GRAYAA
   Color 8 = GRAYCC
   Ratio = 1.33333
   Hsize =     7.5
   Vsize =      10
   F=4

   NOTE: The PROCEDURE GTESTIT used 0:00:02.0 real 0:00:00.30 cpu.

For the PS driver, the default HSIZE is 7.5 inches. The default VSIZE is 10 inches. We are using the V3 template from the SASHELP.TEMPLT catalog, which produces three template panels of equal size, one above the other. For each panel, the V3 template uses 1/3 the vertical area and the entire horizontal area. Therefore, we need only reduce the VSIZE for the graphs to 1/3 of their default values. There is no need to change the value of the HSIZE option.

To avoid any confusion, clear all the graphs out of the WORK.GSEG catalog.

   proc greplay nofs igout=work.gseg;

      delete _all_;
    run;
    quit;

goptions reset=all target=ps ftext=swiss nodisplay hby=0
         vsize=3.3;

proc gchart data=one gout=work.gseg;

   vbar player/ sumvar=rank;

   by position;

   pattern1 v=solid c=black;
   title1 'This is a graph for #byval(position)';
 run;
 quit;

goptions vsize=0 vpos=0 display;

proc greplay nofs igout=work.gseg tc=sashelp.templt 
                template=v3;

   treplay 1:GCHART
           2:GCHART1
           3:GCHART2;
 run;
 quit;