TS-271

AN OVERVIEW OF TRANSPORTING SAS FILES BETWEEN HOSTS
BY David Shinn and David Driggs

ABSTRACT

INTRODUCTION

This article provides an overview of transporting SAS files. It provides numerous system-specific examples, a list of some common problem areas and helpful tips for transporting. While this article discusses transporting in the MVS, CMS, VMS, Windows, OS/2, DOS and UNIX environments, much of the information also applies to other operating systems as well. Transporting is discussed under both Version 6 and Version 5 of the SAS System, however more attention is devoted to transporting under Version 6 of the SAS System.

Since this article is an overview, it does not attempt to provide exhaustive coverage of transporting SAS files or of the various SAS procedures that are discussed here. There are SAS System publications available that provide in depth coverage of these areas. These publications are listed in the SUMMARY section of the article.

GENERAL INFORMATION ABOUT TRANSPORTING

Transport files are sequential files containing SAS data sets, SAS catalogs or a SAS data library in transport format. There are two specific types of transport format. One type is used only for transporting SAS data sets. For example, under Release 6.06, the XPORT engine (which is used on the LIBNAME statement) can be used to create or read a transport file containing this format. The other type of transport format is created by PROC CPORT and must be read by PROC CIMPORT; this format must be used for transporting SAS catalogs.

In addition to using the XPORT engine, there are other tools that can be used to create or read transport files that contain transport format for data sets. However, these tools vary with different releases of the SAS System (and under Release 5.18, vary with different operating systems). The following list summarizes the tools that are available.

• When using Release 6.06 or later, use the XPORT engine.
• When using Release 6.04, use the SASV5XPT engine.
• When using Release 5.18 under MVS, CMS or VSE, use PROC XCOPY.
• When using Release 5.18 under VMS, AOS/VS or PRIMOS, use PROC COPY (with the EXPORT and IMPORT options) or use the TRANSPORT= data set option.

Transport format for SAS data sets (created by the XPORT or SASV5XPT engine or the COPY or XCOPY procedure) is the same for all SAS releases on all host environments. Therefore, a transport file containing this format can be transported to any release of the SAS System on any host. For example, if a transport file is created on Release 6.06 using the XPORT engine, it can be imported on Release 5.18 under CMS using PROC XCOPY or it can be imported on Release 6.04 using the SASV5XPT engine.

Transport format created by PROC CPORT can be recognized by the release on which it was produced or by a later release, but it will not be recognized by an earlier release. For example, if PROC CPORT is used to create a transport file on Release 6.06, this file cannot be imported on Release 5.18.

TRANSPORTING UNDER RELEASE 6.06 OR LATER

The XPORT engine is generally used in conjunction with PROC COPY; using this approach makes it easy to create or read a transport file which contains one or more data sets from a SAS data library. Another approach is to use the SAS DATA step to create or read a transport file; specify the XPORT engine on the LIBNAME statement for the transport file and then create or read the file as you would a regular SAS data set.

In Release 6.06 or later, the CPORT procedure, coupled with PROC CIMPORT can be used to transport SAS catalogs, SAS data sets and SAS data libraries. These procedures are the only tools available for creating and reading transport files containing SAS catalogs.

TRANSPORTING UNDER RELEASE 5.18

When transporting full-screen catalogs on Release 5.18 (under MVS, CMS, VMS, AOS/VS and PRIMOS), use PROC CPORT to create a transport file and PROC CIMPORT to import. On Release 5.18, PROC CPORT and PROC CIMPORT are used only for transporting full-screen catalogs. Graphics catalogs and user-written formats/informats cannot be transported between hosts using Release 5.18. However, if you have Release 6.06 or later running on both the sending and receiving hosts, you can use PROC V5TOV6 to convert these files to Version 6 on the sending host and then transport them.

TRANSPORTING IN THE MVS ENVIRONMENT

SOME COMMON PROBLEMS

Another common problem occurs when communications software is used to move the file from another host to MVS. (In this article, the term communications software is used to refer to communications software that is used for sending or receiving data files.) Occasionally, the transport file does not have the proper DCB characteristics when it arrives on MVS. If the communications software does not allow you to specify file characteristics, try the following approach. First, create a file on MVS with the correct DCB specifications. Then, move the transport file from the other host to the newly created file on MVS using binary transfer.

TRANSPORTING UNDER RELEASE 6.06 OR LATER

In this example, a transport file is written to tape. This job copies all SAS data sets in the SAS data library referenced by the libref OLD to the file referenced by the libref TRAN. Note the DCB characteristics that are used for the output file, TRAN. Also, note that a non-labeled tape is specified.

  //EXAMP1 JOB (,X101),'SMITH,B.',TIME=(0,5)
  // EXEC SAS606
  //TRAN DD DISP=NEW,UNIT=TAPE,
  //     VOL=SER=TRAN01,LABEL=(1,NL),
  //     DCB=(RECFM=FB,LRECL=80,BLKSIZE=8000)
  //SYSIN DD *
  libname old 'actxyz.sales91.sasdata';
  libname tran xport;
  proc copy in=old out=tran memtype=data;
  run;
  /*
 

  //EXAMP2 JOB (,X101),'SMITH,B.',TIME=(0,5)
  // EXEC SAS606
  //TRAN DD DISP=OLD,UNIT=TAPE,
  //     VOL=SER=TRAN02,LABEL=(1,NL),
  //     DCB=(RECFM=FB,LRECL=80,BLKSIZE=8000)
  //NEW DD DSN=ACTXYZ.EMPLOYEE.SASDATA,
  //    DISP=(NEW,CATLG),UNIT=SYSDA,SPACE=(TRK,(20,5))
  //SYSIN DD *
  libname tran xport;
  proc copy in=tran out=new;
    exclude dept10 dept12;
  run;
  /*
        

  //EXAMP3 JOB (,X101),'SMITH,B.',TIME=(0,5)
  // EXEC SAS606
  //PORTFILE DD DISP=NEW,UNIT=TAPE,
  //    VOL=SER=TRAN11,LABEL=(1,NL),
  //    DCB=(RECFM=FB,LRECL=80,BLKSIZE=8000)
  //SYSIN DD *
  libname old 'actxyz.mylib.sascat';
  proc cport library=old file=portfile memtype=catalog
             tape;
  run;
  /*

  //EXAMP4 JOB (,X101),'SMITH,B.',TIME=(0,5)
  // EXEC SAS606
  //PORTFILE DD DISP=OLD,UNIT=TAPE,
  //   VOL=SER=TRAN12,LABEL=(1,NL),
  //   DCB=(RECFM=FB,LRECL=80,BLKSIZE=8000)
  //NEW DD DSN=ACTXYZ.NEWLIB.SASDATA,DISP=(NEW,CATLG),
  //    UNIT=SYSDA,SPACE=(TRK,(30,5))
  //SYSIN DD *
  proc cimport library=new infile=portfile tape;
  run;
  /*

TRANSPORTING UNDER RELEASE 5.18

  libname old 'actxyz.sales91.sasdata';
  proc xcopy in=old out=tran export;
    select jan91 feb91 mar91;
  run;

  proc xcopy in=tran out=new import;
  run;

TRANSPORTING IN THE VMS ENVIRONMENT

SOME COMMON PROBLEMS

If a transport file is created on disk on Release 6.06 under VMS, it will have a record attribute of Carriage Return Carriage Control (but the file does not contain carriage control characters). When the file is moved via communications software, some communications software facilities actually insert a carriage control character after each record; this corrupts the file so that it cannot be imported by the SAS System on the receiving host. For example, this problem most commonly occurs when a transport file is sent to a personal computer or to the UNIX environment. If you get the following error message on a personal computer or under UNIX when trying to import a SAS data set transport file that was created on VMS, then the VMS Carriage Return Carriage Control attribute is probably the cause.

  ERROR: File libref.ALL is damaged.  I/O processing did not
         complete.

  $ DIR/FULL tran-file

If the record attribute of Carriage Return Carriage Control causes problems for you, then use the following approach to change the record attribute to NONE:

  1. Create a file called REMCC.FDL which contains the following:

       RECORD
          BLOCK_SPAN YES
          CARRIAGE_CONTROL NONE
          FORMAT  FIXED
          SIZE  80

  2. Issue the following statement, to create a new file
     called TRANS.NEWDAT with the correct attributes:

       $  CONVERT/FDL=REMCC.FDL TRANS.DAT TRANS.NEWDAT

  3. Issue the following command to confirm that the record
     attribute has been changed to NONE.

       $  DIR/FULL TRANS.NEWDAT

The following example illustrates the use of the CC=NONE option on the LIBNAME statement.

  libname tran xport 'tran1.dat' cc=none;

  proc copy in=work out=tran memtype=data;
  run;

TRANSPORTING UNDER RELEASE 6.06 OR LATER

  1. Issue the appropriate command at your site to make
     a tape drive available to your session.

  2. Issue the following DCL commands to mount the tape.
     You will need to substitute your tape device name in
     place of "$2$MUA0:".

        $ DEFINE TRANFL $2$MUA0:
        $ ALLOCATE TRANFL
        $ MOUNT/FOREIGN/BLOCKSIZE=8000 TRANFL

  3. Then, execute the following program.  The name 'TRANFL'
     on the LIBNAME statement refers to the logical name that
     is associated  with the tape drive.

        libname tport xport 'tranfl';
        libname old '[actxyz.oldlib]';
        proc copy in=old out=tport memtype=data;
        run;

  libname tport xport 'tranfl';
  data sample1;
    set tport.big1 (obs=20);
  run;

  filename tport 'tranfl';
  libname old '[actxyz.oldlib]';
  proc cport catalog=old.mycat file=tport tape;
  run;

  filename tport 'tranfl';
  libname new '[actxyz.newlib]';
  proc cimport library=new infile=tport tape;
  run;

TRANSPORTING UNDER RELEASE 5.18

Use the following approach when writing a data set transport file to tape. First, issue the appropriate command at your site to make a tape drive available to your session. Then, mount the tape with the following commands, where your tape device name is substituted for "$2$MUA0:".

  $ DEFINE IXTAPE $2$MUA0:
  $ ALLOCATE IXTAPE
  $ MOUNT/FOREIGN/BLOCKSIZE=8000 IXTAPE

  libname old  '[actxyz.newlib]';
  proc copy in=old out=ixtape export;
    select apr91 may91 jun91;
  run;

TRANSPORTING IN THE CMS ENVIRONMENT

SOME COMMON PROBLEMS ON CMS

When a transport file is moved via communications software, it is sometimes difficult to move the file so that it retains the correct DCB characteristics on CMS. You may have more success if you logon to CMS and "pull" the file from the other host, rather than logging onto the other host and sending the file to CMS. Also, check the documentation for your communications software to see if there are options that can be set for the DCB characteristics.

Sometimes, when a transport file is moved to CMS via communications software, the file's record length may be changed. If you find that it is not possible, with your communications software, to move the file without changing the file attributes, then the reblocking program in the "Guidelines for Avoiding Problems" section (at the end of this article) may be helpful.

TRANSPORTING UNDER RELEASE 6.06 OR LATER

  cms filedef tran tap1 nl
      (recfm fb lrecl 80 blksize 8000;
  run;
  libname tran xport;
  libname sales91 'b';
  proc copy in=sales91 out=tran;
     select sept91 oct91;
  run;

  cms filedef tran tap1 nl
      (recfm fb lrecl 80 blksize 8000;
  run;
  libname tran xport;
  libname mylib 'a';
  proc copy in=tran out=mylib;
  run;

  filename tran tape 'tap1' lrecl=80 blksize=8000
           recfm=fb label=nl;
  libname dept12 'a';
  proc cport library=dept12 file=tran memtype=catalog
             tape;
  run;

TRANSPORTING UNDER RELEASE 5.18

  cms filedef tran tap1 nl
      (recfm fb lrecl 80 blksize 8000;
  run;
  libname sales89 'c';
  proc xcopy in=sales89 out=tran export;
    exclude oct89 nov89 dec89;
  RUN;

TRANSPORTING IN THE WINDOWS AND OS/2 ENVIRONMENTS

SOME COMMON PROBLEMS

48 45 41 44 45 52 20 52 45 43 4F 52 44 2A 2A 2A HEADER R ECORD***
2A 2A 2A 2A 4C 49 42 52 41 52 59 20 48 45 41 44 ****LIBR ARY HEAD
45 52 20 52 45 43 4F 52 44 21 21 21 21 21 21 21 ER RECOR D!!!!!!!
30 30 30 30 30 30 30 30 30 30 30 30 30 30 30 30 00000000 00000000
30 30 30 30 30 30 30 30 30 30 30 30 30 30 20 20 00000000 000000
0D 0A 53 41 53 20 20 20 20 20 53 41 53 20 20 20 ..SAS     SAS

   ERROR: File libref.ALL is damaged.  I/O processing did not
          complete.

EXAMPLES OF TRANSPORTING ON WINDOWS AND OS/2

The following program causes all data sets in the library referenced by the libref OLD to be copied in transport format to the file on disk (transpt.dat) which is referenced by the libref TRAN.

  libname tran xport 'c:\workdir\transpt.dat';
  libname old 'c:\olddir';
  proc copy in=old out=tran;
  run;

  filename portfl 'a:\mydir\tran1.dat';
  libname old 'a:\olddir';
  proc cport library=old file=portfl memtype=catalog;
  run;

TRANSPORTING IN THE DOS ENVIRONMENT

The following program causes all data sets in the library referenced by the libref OLD to be copied in transport format to the file on disk (transpt.dat) which is referenced by the libref TRAN.

  libname tran sasv5xpt 'c:\workdir\transpt.dat';
  libname old 'c:\olddir';
  proc copy in=old out=tran;
  run;

  filename portfl 'a:\mydir\tran1.dat';
  libname old 'a:\olddir';
  proc cport library=old file=portfl memtype=catalog;
  run;

TRANSPORTING IN THE UNIX ENVIRONMENT AND DERIVATIVES

   dd if=/dev/tape1  of=tran.dat  bs=8000

  libname tran xport '/dev/tape1';
  libname old '/users/myid';
  proc copy in=old out=tran;
    select jul91;
  run;

  libname old '/users/myid/mydir';
  filename portfile '/users/myid/trans1.dat';
  proc cport catalog=old.customer
       file=portfile
       select=(menu1.program menu2.program);
  run;

ANOTHER APPROACH FOR TRANSPORTING: USE SAS/CONNECT

GUIDELINES FOR AVOIDING PROBLEMS

• When transporting a file via communications software, always use BINARY (sometimes called IMAGE) format. The file must be moved byte-for-byte without modification.
• When transporting a file via tape, always use a non-labeled tape. It may be possible to use a standard labeled tape, but it usually requires extra work to read the file on the receiving host.
• You cannot use PROC CIMPORT to import a transport file unless the file was created by PROC CPORT. To determine whether the transport file was created by PROC CPORT, inspect the file by browsing it. For a transport file that was created by PROC CPORT, the first 50 characters (in ASCII) are as follows:

  **COMPRESSED** **COMPRESSED** **COMPRESSED** **COM
  

• If the transport file was created by the XPORT engine, the first 50 characters (in ASCII) are as follows:

  HEADER RECORD*******LIBRARY HEADER RECORD!!!!!!!00
  

• If a carriage control (or any other character) is inserted in a transport file, the file will be corrupted so that it cannot be imported. Some communications software or COPY utilities can insert a carriage control character at the end of each record.
• The file's record length, blocksize or record format must not be modified when the file is copied or moved via communications software or via a copy utility.
• If your communications software changes the file's record length, blocksize or record type, consult your communications software documentation. There is probably an option that permits you to specify a record length of 80, blocksize of 8000 and fixed length records.
• When moving a file via communications software, you may be more successful invoking the facility from the receiving host rather than from the sending host. For example, when moving a transport file from VMS to CMS, you may be more successful if you logon to CMS and invoke the communications software there.
• If the receiving host cannot import the transport file, try importing the file on the same host that created it. If the original host cannot import a file that it created, then the transport file was created incorrectly. It is a good habit to always test a transport file by importing it on the host that created it; if there is a problem, it is important to recognize it immediately.
• If a transport file on the receiving host has an incorrect blocksize and you are unable to obtain a correct transport file, then try using the program shown later in this section to reblock the file. The resulting output file contains 80 byte, fixed length records. This program creates a copy of the transport file that often can be imported, unless the original transport file is corrupted.

  In this example, the record format of the original transport file is fixed and the record length is evenly divisible by 16. If the record format is fixed and the record length of your transport file is not evenly divisible by 16, then determine the greatest common denominator that divides into both 80 and the file record length; then substitute this number for all occurrences of 16 in the program. For example, if your transport file has a record length of 99, then 1 is the largest number that divides evenly into both 80 and 99. If your transport file has variable length records, then use 1 as the greatest common denominator instead of 16.

  One warning should be noted. Sometimes, when a file is moved via communications software, extra null characters are written at the end of the file to pad the remainder of the last record. When this reblocking program is used, any extra null characters in the resulting output file may cause extra observations (all zero values) to be added to the end of the last data set in the library. This can occur when importing a transport file containing SAS data sets (using the XPORT engine, for example).

    data _null_;
       /* Note: the INFILE and FILE statements must */
       /* be modified.  Substitute your file names. */
      infile 'your_transport.dat' eof=wrapup;
      file 'new_transport.dat' recfm=f lrecl=80;
      length inrec $16 outrec $80 nullrec $80;
      retain count 1 outrec nullrec;
      input inrec $char16. @@;
      substr(outrec, count, 16) = inrec;
      count + 16;
      if (count > 80) then do;
         put outrec $char80.;
         count=1;
      end;
      return;
    wrapup:;
      file log;
      nullrec = repeat('00'x,80);
      if outrec = nullrec then do;
        put 'WARNING: Null characters may have been'
         ' added at the end of transport file by'
         ' communications software or by a copy'
         ' utility.  For a dataset transport file,'
         ' this could result in extra null'
         ' observations being added at the end'
         ' of the last dataset.';
      end;
    run;
  

• Problems may occur during importing if your transport file spans more than one tape. Rather than using multi-volume tapes, you should split the original library into two or more libraries and create a separate tape for each one. The original library can be restored of the receiving host.
• It is often helpful to view a transport file in hexadecimal format after it has been transported. If the file has become corrupted, it may be possible to determine this by examining the hexadecimal characters.

  You can use the following method to inspect your file. First, create a sample transport file (that is known to be correct) on the receiving host, and examine it to see what the syntax should look like in hexadecimal. Now, examine the other transport file (the one in question) to see if the syntax of the hexadecimal code corresponds to that in the correct file. If the file has become corrupted, this may be obvious.

SUMMARY

There are publications available that provide much additional information about transporting SAS files, including options not discussed here. The most complete information is available in "SAS Technical Report P-195, Transporting SAS files between Host Systems". Other helpful documentation includes the "SAS Procedures Guide, Version 6, Third Edition", the "SAS Language Reference, Version 6, First Edition", the "SAS Procedures Guide, Release 6.03 Edition" and the "SAS Users Guide to Basics, Version 5 Edition". The "SAS Companions" for various operating systems are also helpful.