FOCUS AREAS

Graphics

Weight by Height for Age < 13
Base SAS: ODS Graphics Procedure: SGPLOT

%let gpath='.';
%let dpi=100;

ods html close;
ods listing gpath=&gpath image_dpi=&dpi;

data class;
  set sashelp.class(where=(age < 13));
  if name='Thomas' then weight=65;
  if name='Louise' then height=55;
run;
proc print;run;

/*--Scatter Plot with Other Symbols 9.4--*/
ods listing style=htmlblue;
ods graphics / reset attrpriority=none noborder width=5in height=3.75in imagename='Symbols_Char_94';
title 'Weight by Height for Age < 13'; 
footnote j=l 'Symbols from Font Character';
proc sgplot data=class;
  symbolchar name=Male char='2642'x / scale=1.6 textattrs=(weight=bold) voffset=0.1;
  symbolchar name=Female char='2640'x  / scale=1.6 textattrs=(weight=bold);
  styleattrs datasymbols=(Male Female);
  scatter x=height y=weight / group=sex markerattrs=(size=48);
  keylegend / location=inside position=topleft across=1 autoitemsize;
  yaxis grid integer offsetmin=0.1 offsetmax=0.1;
  xaxis grid integer;
  run;
  
title;
footnote;