FOCUS AREAS

SAS/ETS Web Examples


Contents | SAS Program | PDF

Estimating a Derived Demand System from a Translog Cost Function

Overview

The transcendental logarithmic (translog) functional form can capture many of the attributes of a cost function that are implied by economic theory. Because of this flexibility, it has been widely used for studying production relationships. Before logarithms are taken, the function is

\begin{equation} \label{badspec} C=a_{0}y^{a_ y}y^{\frac{1}{2}a_{yy}\ln {y}}\prod _{i=1}^{N}w_{i}^{a_ i}\prod _{i=1}^{N}w_{i}^{a_{iy}\ln {y}}\prod _{i=1}^{N}w_{i}^{\frac{1}{2}\sum _{j=1}^{N}a_{ij}\ln {w_{j}}} \end{equation}

The function takes $\mathbf{w}$ and $y$ as its inputs and returns minimum cost, where $\mathbf{w}$ is a vector of prices for the inputs to production and $y$ is a single output. $N$ is the total number of inputs and the $a$’s are the parameters of the function. It may not be apparent from the equation above, but the translog form nests the Cobb-Douglas form and is equivalent if all $a_{ij}$ and $a_{iy}$ are zero.

One disadvantage of the previous form is that it is not linear in parameters. A standard technique when dealing with power functions like the translog cost function is to take logarithms. The resulting function is linear in parameters and standard statistical techniques can be used for estimation. After taking logarithms the function is

\begin{equation} \label{bestspec} \ln C= a_0 + \sum _{i=1}^{N}a_{i}\ln w_{i}+a_{y}\ln y + \frac{1}{2}\sum _{i=1}^{N}\sum _{j=1}^{N}a_{ij}\ln w_{i}\ln w_{j} + \sum _{i=1}^{N}a_{iy}\ln w_{i}\ln y +\frac{1}{2}a_{yy}\ln y\ln y \end{equation}

While it is possible to include terms to account for technological progress, the specification used here assumes that cost is independent of time. Using Shepherd’s lemma, the derived demand equations are

\begin{equation}  s_ i = a_ i + a_{iy}\ln y + \sum _{j=1}^{N} a_{ij}\ln w_{j} \end{equation}

where $s_ i = \frac{w_{i}x_{i}}{C}$ is the cost share of the $i$th input. The cost function is assumed to be continuous, so Young’s Theorem concerning symmetry of the second derivatives restricts

\begin{equation}  a_{ij}=a_{ji} \end{equation}

for all $i \ne j$.

The result of this derivation is a system of $N+1$ equations consisting of $N$ derived demand equations and one cost function.

Homogeneity of the first degree implies

\begin{equation}  \sum _{i=1}^{N}a_{i}=1, \sum _{j=1}^{N}a_{ij}=0, \sum _{i=1}^{N}a_{iy}=0 \end{equation}

for all $i$ and $j$.

It is also possible to impose constant returns to scale – equivalent to imposing homogeneity in $y$ – and details of this procedure can be found in Diewert and Wales (1987). Global concavity can also be imposed on this specification by forcing the matrix $[a_{ij}]$ to be negative semidefinite. A technique for accomplishing this can be found in Jorgenson (1986). This procedure tends to restrict the price elasticities in an undesirable way and destroys the flexibility of the form.

Analysis

This example shows the estimation of a system of nonlinear derived demand equations based on a translog cost function using iterated seemingly unrelated regression (ITSUR). Data pertains to the United States textiles manufacturing sector (standard industrial classification code 22). The series runs from 1949 to 2001 and contains real quantity indices, real price indices, and real cost measures for a single aggregate industry output and five aggregate inputs: capital (K), labor (L), energy (E), materials (M), and services (S). The original dataset, and information on other industrial sectors, can be obtained from the Multifactor Productivity Home Page of the Bureau of Labor Statistics at http://www.bls.gov/mfp/.

Derived demand equations are each expressed with a cost share as the endogenous variable. Because this dataset does not contain explicit information on cost shares, the shares must be formed by taking the ratio of the value of each input and the cost measure.

data klems;
set klems;
   array values {5} vk vl ve vm vs;
   array costshares {5} sk sl se sm ss;
   cost = sum(vk,vl,ve,vm,vs);
   do i = 1 to 5;
     costshares{i} = values{i}/cost;
   end;
run;

A plot of the cost shares over time is produced by the following statements.

proc sgplot data = klems;
   series x = year y = sk / markers markerattrs =(symbol=circle);
   series x = year y = sl / markers markerattrs =(symbol=square);
   series x = year y = se / markers markerattrs =(symbol=star);
   series x = year y = sm / markers markerattrs =(symbol=diamond);
   series x = year y = ss / markers markerattrs =(symbol=hash);
   title 'Factor Cost Shares';
   yaxis label = 'Cost Share';
run;

Figure 1: Change in Cost Shares

Change in Cost Shares


One benefit of the translog form is that the system of factor demands gives nearly the same information as the cost function. The only parameter of the cost function that is not captured by the derived demand system is the intercept term which is not used in calculating price or substitution elasticities. To be as parsimonious as possible, the cost function is typically not estimated.

In this example, the MODEL procedure is used to fit four derived demand equations. One of the equations (the derived demand equation for services) has been arbitrarily dropped from estimation; only $N-1$ of the factor demands are linearly independent because the dependent variables are cost shares which must sum to one. The parameters of the dropped derived demand equation can be recovered after estimation through homogeneity and symmetry restrictions.

The following statements estimate the system of derived demand equations without imposing any restrictions from theory. Likelihood ratio tests are conducted to determine whether homogeneity and symmetry are satisfied both singularly and jointly.

   proc model data = klems;
      parameters a_k gkk gkl gke gkm gks gky
       	         a_l glk gll gle glm gls gly
	                 a_e gek gel gee gem ges gey
	                 a_m gmk gml gme gmm gms gmy;
      endogenous sk sl se sm;
      exogenous pk pl pe pm ps y;

      /*System of Derived Demand Equations*/
      sk = a_k + gkk*log(pk) + gkl*log(pl) + gke*log(pe) + gkm*log(pm) + gks*log(ps)
               + gky*log(y);
      sl = a_l + glk*log(pk) + gll*log(pl) + gle*log(pe) + glm*log(pm) + gls*log(ps)
               + gly*log(y);
      se = a_e + gek*log(pk) + gel*log(pl) + gee*log(pe) + gem*log(pm) + ges*log(ps)
               + gey*log(y);
      sm = a_m + gmk*log(pk) + gml*log(pl) + gme*log(pe) + gmm*log(pm) + gms*log(ps)
               + gmy*log(y);

      fit sk sl se sm / itsur;

      test "Homogeneity"
         gkk+gkl+gke+gkm+gks=0,
         glk+gll+gle+glm+gls=0,
         gek+gel+gee+gem+ges=0,
         gmk+gml+gme+gmm+gms=0, / lr;

      test "Symmetry"
         gkl=glk,
         gke=gek,
         gkm=gmk,
         glm=gml,
         gle=gel,
         gem=gme, / lr;

      test "Joint Homogeneity and Symmetry"
         gkk+gkl+gke+gkm+gks=0,
         glk+gll+gle+glm+gls=0,
         gek+gel+gee+gem+ges=0,
         gmk+gml+gme+gmm+gms=0,
         gkl=glk,
         gke=gek,
         gkm=gmk,
         glm=gml,
         gle=gel,
         gem=gme, / lr;
   run;

Because the form of the elasticities is somewhat complicated, it can be difficult to interpret the values and signs of parameter estimates. The test results in Figure 2 show that both symmetry and homogeneity are rejected. A common practice is to assume that such restrictions hold and to impose them in estimation.

Figure 2: Tests of Symmetry and Homogeneity

The MODEL Procedure

Test Results
Test Type Statistic Pr > ChiSq Label
Homogeneity L.R. 114.22 <.0001 gkk+gkl+gke+gkm+gks=0, glk+gll+gle+glm+gls=0, gek+gel+gee+gem+ges=0, gmk+gml+gme+gmm+gms=0
Symmetry L.R. 109.72 <.0001 gkl=glk, gke=gek, gkm=gmk, glm=gml, gle=gel, gem=gme
Joint Homogeneity and Symmetry L.R. 240.80 <.0001 gkk+gkl+gke+gkm+gks=0, glk+gll+gle+glm+gls=0, gek+gel+gee+gem+ges=0, gmk+gml+gme+gmm+gms=0, gkl=glk, gke=gek, gkm=gmk, glm=gml, gle=gel, gem=gme


The following code imposes both symmetry and homogeneity restrictions on the underlying model. A likelihood ratio test of constant returns to scale is introduced and a Chow test is added to the FIT statement.

   proc model data = klems;
       parameters a_k gkk gkl gke gkm gks gky
                  a_l glk gll gle glm gls gly
                  a_e gek gel gee gem ges gey
                  a_m gmk gml gme gmm gms gmy;
       endogenous sk sl se sm;
       exogenous pk pl pe pm ps y;
       restrict /*Homogeneity Restrictions*/
                gks=0-gkk-gkl-gke-gkm,
                gls=0-gkl-gll-gle-glm,
                ges=0-gke-gle-gee-gem,
                gms=0-gkm-glm-gem-gmm,
                /*Symmetry Restrictions*/
                gkl=glk, gke=gek, gkm=gmk, gle=gel, glm=gml, gem=gme;

       /*System of Derived Demand Equations*/
       sk = a_k + gkk*log(pk) + gkl*log(pl) + gke*log(pe) + gkm*log(pm) + gks*log(ps)
                + gky*log(y);
       sl = a_l + glk*log(pk) + gll*log(pl) + gle*log(pe) + glm*log(pm) + gls*log(ps)
                + gly*log(y);
       se = a_e + gek*log(pk) + gel*log(pl) + gee*log(pe) + gem*log(pm) + ges*log(ps)
                + gey*log(y);
       sm = a_m + gmk*log(pk) + gml*log(pl) + gme*log(pe) + gmm*log(pm) + gms*log(ps)
                + gmy*log(y);

       fit sk sl se sm / itsur chow = (24) outest=est;

       test "Constant Returns to Scale"
          gky=0,
          gly=0,
          gey=0,
          gmy=0, / lr;
   run;

The symmetry restriction shrinks the number of parameters of the model considerably. This is particularly useful in cases where the time series is not long and degrees of freedom need to be conserved. Figure 3 shows the parameter estimates of the MODEL procedure.

Figure 3: The Restricted Model

The MODEL Procedure

Nonlinear ITSUR Parameter Estimates
Parameter Estimate Approx Std Err t Value Approx
Pr > |t|
Label
a_k 0.109996 0.0219 5.02 <.0001 SK Intercept
gkk 0.062014 0.00357 17.38 <.0001 SK K Price
gkl -0.01898 0.00725 -2.62 0.0118 SK L Price
gke -0.00179 0.000836 -2.15 0.0369 SK E Price
gkm -0.03872 0.00610 -6.35 <.0001 SK M Price
gks -0.00252 0.00342 -0.74 0.4648 SK S Price
gky -0.00104 0.00496 -0.21 0.8354 SK Output
a_l 0.865473 0.0903 9.58 <.0001 SL Intercept
glk -0.01898 0.00725 -2.62 0.0118 SL K Price
gll -0.00999 0.0360 -0.28 0.7826 SL L Price
gle -0.00106 0.00420 -0.25 0.8013 SL E Price
glm -0.06766 0.0248 -2.73 0.0087 SL M Price
gls 0.097692 0.0214 4.57 <.0001 SL S Price
gly -0.11488 0.0200 -5.74 <.0001 SL Output
a_e 0.012747 0.00984 1.30 0.2013 SE Intercept
gek -0.00179 0.000836 -2.15 0.0370 SE K Price
gel -0.00106 0.00420 -0.25 0.8013 SE L Price
gee 0.029876 0.00112 26.76 <.0001 SE E Price
gem -0.01954 0.00275 -7.12 <.0001 SE M Price
ges -0.00748 0.00325 -2.30 0.0257 SE S Price
gey 0.005808 0.00217 2.68 0.0101 SE Output
a_m -0.08173 0.0701 -1.17 0.2492 SM Intercept
gmk -0.03872 0.00610 -6.35 <.0001 SM K Price
gml -0.06766 0.0248 -2.73 0.0087 SM L Price
gme -0.01954 0.00275 -7.12 <.0001 SM E Price
gmm 0.146849 0.0222 6.62 <.0001 SM M Price
gms -0.02092 0.0103 -2.03 0.0477 SM S Price
gmy 0.113729 0.0157 7.27 <.0001 SM Output
Restrict0 -563.453 242.8 -2.32 0.0187 gks=0-gkk-gkl-gke-gkm
Restrict1 82.23307 193.0 0.43 0.6747 gls=0-gkl-gll-gle-glm
Restrict2 321.7446 689.2 0.47 0.6455 ges=0-gke-gle-gee-gem
Restrict3 -279.71 211.0 -1.33 0.1879 gms=0-gkm-glm-gem-gmm
Restrict4 -261.228 196.3 -1.33 0.1860 gkl=glk
Restrict5 -1041.84 755.0 -1.38 0.1700 gke=gek
Restrict6 -27.855 219.3 -0.13 0.9005 gkm=gmk
Restrict7 -880.821 742.7 -1.19 0.2396 gle=gel
Restrict8 259.513 215.6 1.20 0.2326 glm=gml
Restrict9 1103.343 320.8 3.44 0.0003 gem=gme


The majority of the parameter estimates are significant. Insignificant parameters are statistically equivalent to zero and imply that corresponding elasticities of substitution are equal to the Cobb-Douglas value of one.

The TEST statement tests whether this industry exhibits constant returns to scale in the range of the sample. The CHOW option in the FIT statement performs a Chow test for a structural break at the twenty-fourth year of the sample. The twenty-fourth year of the sample is 1973; in October of that year OPEC declared an oil embargo. Markets were affected by significant shocks to oil prices and gasoline was rationed in the United States. The results of the two tests can be seen in Figure 4.

Figure 4: CRS and Chow Test Results

Test Results
Test Type Statistic Pr > ChiSq Label
Constant Returns to Scale L.R. 74.27 <.0001 gky=0, gly=0, gey=0, gmy=0

Structural Change Test
Test Break Point Num DF Den DF F Value Pr > F
Chow 24 23 2 0.28 0.9560


The null hypothesis of constant returns to scale is rejected. The null hypothesis of the Chow Test cannot be rejected. Even with the turmoil of the oil embargo, there is no evidence of a structural break in 1973.

Parameter estimates are stored in the est dataset and used in calculating price elasticities and elasticities of substitution in the example "Calculating Elasticities from a Translog Cost Function."

References

  • Blackorby, C., and Russell, R. R. (1989). “Will the Real Elasticity of Substitution Please Stand Up? (A Comparison of the Allen/Uzawa and Morishima Elasticities).” American Economic Review 79:882–888.

  • Chambers, R. G. (1988). Applied Production Analysis: A Dual Approach. New York: Cambridge University Press.

  • Diewert, W. E., and Wales, T. J. (1987). “Flexible Functional Forms and Global Curvature Conditions.” Econometrica 55:43–68.

  • Jorgenson, D. (1986). “Econometric Methods for Modeling Producer Behavior.” In Handbook of Econometrics, edited by Z. Griliches, and M. D. Intriligator, 1841–1915. Amsterdam: North-Holland.