Chapter Contents

Previous

Next

Getting Started

  
*----------------- Data on Physical Fitness -----------------*
| These measurements were made on men involved in a physical |
| fitness course at N.C. State University.                   |
| Only selected variables of                                 |
| Oxygen (oxygen intake, ml per kg body weight per minute),  |
| Runtime (time to run 1.5 miles in minutes), and            |
| RunPulse (heart rate while running) are used.              |
| Certain values were changed to missing for the analysis.   |
*------------------------------------------------------------*;

  
   data FitMiss;
      input Oxygen RunTime RunPulse @@;
      datalines;
   44.609  11.37  178     45.313  10.07  185  
   54.297   8.65  156     59.571    .      .  
   49.874   9.22    .     44.811  11.63  176  
     .     11.95  176          .  10.85    .  
   39.442  13.08  174     60.055   8.63  170  
   50.541    .      .     37.388  14.03  186  
   44.754  11.12  176     47.273    .      .  
   51.855  10.33  166     49.156   8.95  180  
   40.836  10.95  168     46.672  10.00    .  
   46.774  10.25    .     50.388  10.08  168  
   39.407  12.63  174     46.080  11.17  156  
   45.441   9.63  164       .      8.92    .  
   45.118  11.08    .     39.203  12.88  168  
   45.790  10.47  186     50.545   9.93  148  
   48.673   9.40  186     47.920  11.50  170  
   47.467  10.50  170  
   ;

Suppose that the data are multivariate normally distributed and the missing data are missing at random (MAR). That is, the probability that an observation is missing can depend on the observed variable values of the individual, but not on the missing variable values of the individual. See the "Statistical Assumptions for Multiple Imputation" section for a detailed description of the MAR assumption.

The following statements invoke the MI procedure and impute missing values for the FitMiss data set.

   proc mi data=FitMiss seed=37851 mu0=50 10 180 out=outmi;   
      var Oxygen RunTime RunPulse; 
   run;

The "Model Information" table describes the method used in the multiple imputation process. By default, the procedure uses the Markov Chain Monte Carlo (MCMC) method with a single chain to create five imputations. The posterior mode, the highest observed-data posterior density, with a noninformative prior, is computed from the EM algorithm and is used as the starting value for the chain.

The MI procedure takes 200 burn-in iterations before the first imputation and 100 iterations between imputations. In a Markov chain, the information in the current iteration has influence on the state of the next iteration. The burn-in iterations are iterations in the beginning of each chain that are used both to eliminate the series of dependence on the starting value of the chain and to achieve the stationary distribution. The between-imputation iterations in a single chain are used to eliminate the series of dependence between the two imputations.

The "Missing Data Patterns" table lists distinct missing data patterns with corresponding frequencies and percents. Here, an "X" means that the variable is observed in the corresponding group and a "." means that the variable is missing. The table also displays group-specific variable means. The MI procedure sorts the data into groups based on whether an individual's value is observed or missing for each variable to be analyzed. For a detailed description of missing data patterns, see the "Missing Data Patterns" section.

After the completion of m imputations, the "Multiple Imputation Variance Information" table displays the between-imputation variance, within-imputation variance, and total variance for combining complete-data inferences. It also displays the degrees of freedom for the total variance. The relative increase in variance due to missing values and the fraction of missing information for each variable are also displayed. A detailed description of these statistics is provided in the "Combining Inferences from Multiply Imputed Data Sets" section.

The following "Multiple Imputation Parameter Estimates" table displays the estimated mean and standard error of the mean for each variable. The inferences are based on the t distribution. The table also displays a 95% confidence interval for the mean and a t statistic with the associated p-value for the hypothesis that the population mean is equal to the value specified with the MU0= option. A detailed description of these statistics is provided in the "Combining Inferences from Multiply Imputed Data Sets" section.

In addition to the output tables, the procedure also creates a data set with imputed values. The imputed data sets are stored in the outmi data set, with the index variable _Imputation_ indicating the imputation numbers. The data set can now be analyzed using standard statistical procedures with _Imputation_ as a BY variable.

The following statements list the first ten observations of data set outmi.

   proc print data=outmi (obs=10);
     title 'First 10 Observations of the Imputed Data Set';
   run;

The table shows that the precision of the imputed values differs from the precision of the observed values. You can use the ROUND= option to make the imputed values consistent with the observed values.

Chapter Contents

Previous

Next

Top

Copyright © 2001 by SAS Institute Inc., Cary, NC, USA. All rights reserved.