Example 1.1: Clipping Histogram Bars

The CAPABILITY Procedure

Example 1.1: Clipping Histogram Bars

A semiconductor manufacturer produces printed circuit boards that are sampled to determine whether the thickness of their copper plating lies between a lower specification limit of 3.45 mils and an upper specification limit of 3.55 mils. The plating process is assumed to be in statistical control. The plating thicknesses of 100 boards are saved in a data set named trans, created by the following statements:

   data trans;
      input thick @@;
      label thick = 'Plating Thickness (mils)';
      datalines;
   3.468 3.488 3.509 3.506 3.481 3.492 3.478 3.546 3.502 3.512
   3.490 3.482 3.498 3.519 3.504 3.469 3.497 3.495 3.508 3.523
   3.449 3.488 3.463 3.500 3.549 3.525 3.461 3.489 3.514 3.470
   3.461 3.506 3.464 3.489 3.524 3.531 3.501 3.495 3.543 3.510
   3.481 3.497 3.461 3.513 3.528 3.496 3.533 3.480 3.516 3.476
   3.512 3.550 3.481 3.541 3.549 3.531 3.468 3.494 3.522 3.520
   3.505 3.523 3.475 3.470 3.507 3.536 3.528 3.477 3.536 3.491
   3.510 3.461 3.531 3.502 3.491 3.506 3.539 3.513 3.496 3.539
   3.469 3.481 3.515 3.535 3.460 3.475 3.488 3.515 3.484 3.482
   3.517 3.483 3.467 3.467 3.502 3.471 3.516 3.474 3.500 3.466
   ;

The following statements create the histogram shown in Output 1.1.1. Note that the BARLABEL=PERCENT option displays a label above each histogram bar indicating the percentage of observations represented by that bar.

   title 'Process Capability Analysis of Plating Thickness';
   proc capability data=trans noprint;
      spec lsl = 3.45 llsl = 2 clsl = black
           usl = 3.55 lusl = 2 cusl = black;
      histogram thick / cframe   = ligr
                        cfill    = blue
                        barlabel = percent;
   run;

Output 1.1.1: Histogram with Bar Labels

You can use the CLIPSPEC= option to clip histogram bars at the specification limits. A histogram bar intersected by a specification limit is clipped only when no observations lie outside that limit, so clipped bars indicate that all observations are within specifications. These statements create the histogram shown in Output 1.1.2:

   title 'Process Capability Analysis of Plating Thickness';
   proc capability data=trans noprint;
      spec lsl = 3.45 llsl = 2 clsl = black
           usl = 3.55 lusl = 2 cusl = black;
      histogram thick / cframe   = ligr
                        cfill    = blue
                        barlabel = percent
                        clipspec = clip;
   run;

Output 1.1.2: Histogram with Bar Clipping

The maximum observation in the trans data set is 3.55, which is equal to the upper specification limit (USL). Therefore, the rightmost histogram bar in Output 1.1.2 is clipped at the USL, because no observations lie outside that limit. The lower specification limit (LSL) intersects the leftmost histogram bar. However, the minimum observation is 3.449, which is less than the LSL of 3.45. Therefore, the leftmost histogram bar is not clipped.

Chapter Contents
Previous
Next
Top