Example 3.2: Airline Data

The ARIMA Procedure

Example 3.2: Airline Data

This is a test example where an additive outlier at observation number 50 and a level shift at observation number 100 are artificially introduced in the well-known airline passenger data, the Series G in Box and Jenkins (1976).

   data airline;
      set sashelp.air;
      logair = log(air);
      if _n_ = 50 then logair = logair - 0.25;
      if _n_ >= 100 then logair = logair + 0.5;
   run;

The "Airline model," ARIMA(0, 1, 1) ×(0, 1, 1)₁₂, is known to be a good fit to the unmodified log-transformed airline passenger series. The preliminary identification steps (not shown) again suggest the Airline model for the modified data because they exhibit a strong trend and seasonal behavior, and the Airline model has wide applicability in such cases.

   proc arima data=airline;
      identify var=logair( 1, 12 )  noprint;
      estimate q=(1)(12) noint method=ml;
      outlier maxnum=3 alpha=0.01;
   run;

A portion of the estimation and outlier detection output is shown in Output 3.2.1.

Output 3.2.1: Output of Airline Model

The ARIMA Procedure

Maximum Likelihood Estimation
Parameter	Estimate	Standard Error	t Value	Approx Pr > \|t\|	Lag
MA1,1	0.20390	0.08309	2.45	0.0141	1
MA2,1	0.76150	0.07875	9.67	<.0001	12

Variance Estimate	0.004689
Std Error Estimate	0.068479
AIC	-318.305
SBC	-312.555
Number of Residuals	131

Model for variable logair
Period(s) of Differencing	1,12

No mean term in this model.

Outlier Summary
Maximum number searched	3
Number found	3
Significance used	0.01

Outlier Table
Obs	Type	Estimate	Chi-Square	Approx Prob>ChiSq
100	Shift	0.49325	199.36	<.0001
50	Additive	-0.27508	104.78	<.0001
135	Additive	-0.10488	13.08	0.0003

Clearly the level shift at observation number 100 and the additive outlier at observation number 50 are the dominant outliers. Moreover, the corresponding regression coefficients seem to correctly estimate the size and sign of the change. You can augment the airline data with these two regressors.

   data airline;
      set airline;
      if _n_ = 50 then AO = 1;
      else AO = 0.0;
      if _n_ >= 100 then LS  = 1;
      else LS = 0.0;
   run;

You can now refine the previous model by including these regressors. Note that the differencing order of the dependent series is matched to the differencing orders of the outlier regressors to get the correct "effective" outlier signatures.

   proc arima data=airline;
      identify var=logair(1, 12) 
         crosscorr=( AO(1, 12) LS(1, 12) ) noprint;
      estimate q=(1)(12) noint 
         input=(AO LS) method=ml plot;
      outlier maxnum=3 alpha=0.01;
   run;

The estimation and outlier detection results are shown in Output 3.2.2.

Output 3.2.2: Airline Model with Outliers

The ARIMA Procedure

Maximum Likelihood Estimation
Parameter	Estimate	Standard Error	t Value	Approx Pr > \|t\|	Lag	Variable	Shift
MA1,1	0.39529	0.08117	4.87	<.0001	1	logair	0
MA2,1	0.55870	0.08678	6.44	<.0001	12	logair	0
NUM1	-0.27421	0.02761	-9.93	<.0001	0	AO	0
NUM2	0.49913	0.02985	16.72	<.0001	0	LS	0

Variance Estimate	0.001382
Std Error Estimate	0.037173
AIC	-482.191
SBC	-470.69
Number of Residuals	131

No mean term in this model.

Outlier Summary
Maximum number searched	3
Number found	3
Significance used	0.01

Outlier Table
Obs	Type	Estimate	Chi-Square	Approx Prob>ChiSq
135	Additive	-0.10310	12.63	0.0004
62	Additive	-0.08872	12.33	0.0004
29	Additive	0.08686	11.66	0.0006

The output shows that a few outliers still remain to be accounted for and that the model could be refined further.

Chapter Contents
Previous
Next
Top