Example 7.2: Crossover Clinical Trial

The LOGISTIC Procedure

Example 7.2: Crossover Clinical Trial

One common use of conditional logistic regression is in a crossover clinical trial. In this example, the subjects are given a sequence of drugs and their response to each drug is recorded. Each subject is considered to be a separate stratum. The goal is to determine if the drugs have the same effect, adjusting for period and carryover effects. In this example, researchers give 15 different subjects three different drugs (A, B, P=placebo) in three consecutive periods (P1, P2, P3), and their response in each period is 1 for improvement and 0 for no improvement. The carryover effect is a classification variable indicating which drug was given in the preceding period:

   data Crossover (drop=P1 P2 P3);
      input Subject P1$ P2$ P3$ Improve @@; 
      Period=1; Drug=P1; Carry='0'; output; 
      input Improve @@; 
      Period=2; Drug=P2; Carry=P1;  output; 
      input Improve @@;   
      Period=3; Drug=P3; Carry=P2;  output;
      datalines;
   1  A B P 0 0 0    8  B P A 0 0 1
   2  A B P 1 1 0    9  B P A 1 0 1
   3  A B P 0 1 1    10 B P A 0 1 0
   4  A P B 1 0 1    11 P A B 0 1 0
   5  A P B 1 0 0    12 P B A 1 0 1
   6  B A P 0 0 0    13 P B A 0 0 1
   7  B A P 1 1 0    14 P B A 0 1 0
                     15 P B A 0 1 1
   ;

The model to be fit is

${logit}(\pi_{hi}) &=& \alpha_h + I({\hv Drug}_{hi}=A)\beta_1 +I({\hv Drug}_{hi}=B)\beta_2 \ &&+I(i=1)\beta_3 +I(i=2)\beta_4 \$

where h indexes the subject, $\alpha_h$ are the subject intercepts, i indexes the period, and the I(·) are indicator variables taking the value 1 when the condition is true. Note that this model ignores carryover effects. The following statements perform the analysis:

   proc logistic data=Crossover descending exactonly;
      class Subject Drug Period/ param=ref;
      model Improve=Subject Drug Period;
      exact Drug Period/ joint;
   run;

The exact conditional score p-value for the test of significance of all the parameters is 0.1835; hence, you cannot reject the null hypothesis. However, the exact conditional score p-value for the test of no drug effects, $\beta_1=\beta_2=0$ , is 0.0583, while the p-value for the test of no period effects, $\beta_3=\beta_4=0$ , is 0.8605, which suggests that the period term should be dropped from this model.

Chapter Contents
Previous
Next
Top