Vector Autoregressive Process

The VARMAX Procedure

Vector Autoregressive Process

Let y_t = (y_1t, ... ,y_kt)', t = 0, 1, ... , denote a k-dimensional time series vector of random variables of interest. The pth-order VAR process is written as

$y_{t}={\delta} + \Phi_1{y}_{t-1} + ... + \Phi_p{y}_{t-p} + {\epsilon}_t$

where the ${\epsilon}_t$ is a vector white noise process with ${\epsilon}_t=(\epsilon_{1t}, ... ,\epsilon_{kt})'$ such that ${\rm E}({\epsilon}_t)=0$ , ${\rm E}({\epsilon}_t{\epsilon}_t')=\Sigma$ , and ${\rm E}({\epsilon}_t{\epsilon}_s')=0$ for $t \ne s$ .

Analyzing and modeling the series jointly enables you to understand the dynamic relationships over time among the series and to improve the accuracy of forecasts for individual series by utilizing the additional information available from the related series and their forecasts.

Example of Vector Autoregressive Model

Consider the first-order stationary vector autoregressive model

$y_{t}=( 1.2 & -0.5 \ 0.6 & 0.3 \ ) y_{t-1} + {{\epsilon}}_t, {\rm with} \Sigma=( 1.0 & 0.5 \ 0.5 & 1.25 \ ).$

The following IML procedure statements check whether the specified vector time series model is stationary and simulate a bivariate vector time series from this model to provide test data for the VARMAX procedure:

   proc iml;
      sig = {1.0  0.5, 0.5 1.25};
      phi = {1.2 -0.5, 0.6 0.3};
      /* to simulate the vector time series */
      call varmasim(y,phi) sigma = sig n = 100 seed = 34657;   
      cn = {'y1' 'y2'};
      create simul1 from y[colname=cn];
      append from y;
   quit;

The following statements plot the simulated vector time series y_t shown in Figure 4.1:

   data simul1;
      set simul1;
      t+1;

   proc gplot data=simul1;
      symbol1 v = none i = join l = 1;
      symbol2 v = none i = join l = 2;
      plot y1 * t = 1 
           y2 * t = 2 / overlay;
   run;

Figure 4.1: Plot of Generated Data Process

The following statements fit a VAR(1) model to the simulated data. You first specify the input data set in the PROC VARMAX statement. Then, you use the MODEL statement to read the time series y₁ and y₂. To estimate a VAR model with mean zero, you specify the order of the autoregressive model with the P= option and the NOINT option. The MODEL statement fits the model to the data and prints parameter estimates and various diagnostic tests. The LAGMAX=3 option is used to print the output for the residual diagnostic checks. For the forecasts, you specify the OUTPUT statement. If you wish to forecast five steps ahead, you use the option LEAD=5.

The VARMAX procedure output is shown in Figure 4.2 through Figure 4.9.

   proc varmax data=simul1;
      id date interval=year; 
      model y1 y2 / p=1 noint lagmax=3;
      output lead=5;
   run;

The VARMAX Procedure

Number of Observations	100
Number of Pairwise Missing	0

Variable	Type	NoMissN	Mean	StdDev	Min	Max
y1	DEP	100	-0.21653	2.78210	-4.75826	8.37032
y2	DEP	100	0.16905	2.58184	-6.04718	9.58487

The VARMAX Procedure

Type of Model	VAR(1)
Estimation Method	Least Squares Estimation

Figure 4.2: Descriptive Statistics and Model Type

The VARMAX procedure first displays descriptive statistics and the type of the fitted model for the simulated data, as shown in Figure 4.2.

The VARMAX Procedure

AR Coefficient Estimates
Lag	Variable	y1	y2
1	y1	1.15977	-0.51058
	y2	0.54634	0.38499

Model Parameter Estimates
Equation	Parameter	Estimate	Std Error	T Ratio	Prob>\|T\|	Variable
y1(t)	AR1_1_1	1.15977	0.05508	21.06	0.0001	y1(t-1)
	AR1_1_2	-0.51058	0.05898	-8.66	0.0001	y2(t-1)
y2(t)	AR1_2_1	0.54634	0.05779	9.45	0.0001	y1(t-1)
	AR1_2_2	0.38499	0.06188	6.22	0.0001	y2(t-1)

Figure 4.3: Parameter Estimates

Figure 4.3 shows the AR coefficient matrix in terms of lag 1, the parameter estimates, and their significances that indicate how well the model fits the data. The first column gives the left-hand-side variable of the equation; the second column, the parameter name ARl_i_j, which indicates the (i,j)th element of the lag l autoregressive coefficient; the last column, the regressor corresponding to its parameter.

The fitted VAR(1) model with estimated standard errors in parentheses is given as

$y_t=( 1.160 & -0.511 \ (0.055)&(0.059)\ 0.546 & 0.385 \ (0.058)&(0.062)\ ) y_{t-1} + {\epsilon}_t.$

Clearly, all parameter estimates in the coefficient matrix $\Phi_1$ are significant.

The model can also be written as two univariate regression equations.

$y_{1t} &=& 1.160 y_{1,t-1} - 0.511 y_{2,t-1} + \epsilon_{1t}\ y_{2t} &=& 0.546 y_{1,t-1} + 0.385 y_{2,t-1} + \epsilon_{2t} \$

The VARMAX Procedure

Covariance Matrix for the Innovation
Variable	y1	y2
y1	1.28875	0.39751
y2	0.39751	1.41839

Information Criteria
AICC(Corrected AIC)	0.554443
HQC(Hannan-Quinn Criterion)	0.595201
AIC(Akaike Information Criterion)	0.552777
SBC(Schwarz Bayesian Criterion)	0.65763
FPEC(Final Prediction Error Criterion)	1.738092

Figure 4.4: Innovation Covariance Estimates and Information Criteria

The table in Figure 4.4 shows the innovation covariance matrix estimates and the various information criteria results. The smaller value of information criteria fits the data better when it is compared to other models.

The VARMAX Procedure

Residual Cross-Correlation Matrices
Lag	Variable	y1	y2
0	y1	1.00000	0.28113
	y2	0.28113	1.00000
1	y1	0.01309	0.02385
	y2	-0.05569	-0.07328
2	y1	0.05277	0.06052
	y2	0.00847	-0.04307
3	y1	-0.00163	0.06800
	y2	-0.01644	0.05422

Schematic Representation of Residual Cross Correlations
Variable/Lag	0	1	2	3
y1	++	..	..	..
y2	++	..	..	..
*+ is > 2std error, - is < -2std error, . is between*

Figure 4.5: Multivariate Diagnostic Checks

The VARMAX Procedure

Portmanteau Test for Residual Cross Correlations
To Lag	Chi-Square	DF	Prob>ChiSq
2	1.84	4	0.7659
3	2.57	8	0.9582

Figure 4.6: Multivariate Diagnostic Checks Continued

Figure 4.5 and Figure 4.6 show tests for white noise residuals. The output shows that you cannot reject the hypothesis that the residuals are uncorrelated.

The VARMAX Procedure

Univariate Model Diagnostic Checks
Variable	R-square	StdDev	F Value	Prob>F
y1	0.8369	1.1352	497.67	<.0001
y2	0.7978	1.1910	382.76	<.0001

Figure 4.7: Univariate Diagnostic Checks

The VARMAX procedure provides diagnostic checks for the univariate form of the equations. The table in Figure 4.7 describes how well each univariate equation fits the data. From two univariate regression equations in Figure 4.3, the values of R² in the second column are 0.84 and 0.80 for each equation. The standard deviations in the third column are the square root of the diagonal elements of the covariance matrix from Figure 4.4. The F statistics are in the fourth column for hypotheses to test $\phi_{11}=\phi_{12}=0$ and $\phi_{21}=\phi_{22}=0$ , respectively, where $\phi_{ij}$ is the (i,j)th element of the matrix $\Phi_1$ . The last column shows the p-values of the F statistics. The results show that each univariate model is significant.

The VARMAX Procedure

Univariate Model Diagnostic Checks
Variable	DW(1)	Normality ChiSq	Prob>ChiSq	ARCH1 F Value	Prob>F
y1	1.97	3.32	0.1900	0.13	0.7199
y2	2.14	5.46	0.0653	2.10	0.1503

Univariate Model Diagnostic Checks
Variable	AR1 F Value	Prob>F	AR1-2 F Value	Prob>F	AR1-3 F Value	Prob>F	AR1-4 F Value	Prob>F
y1	0.02	0.8980	0.14	0.8662	0.09	0.9629	0.82	0.5164
y2	0.52	0.4709	0.41	0.6650	0.32	0.8136	0.32	0.8664

Figure 4.8: Univariate Diagnostic Checks Continued

The check for white noise residuals in terms of the univariate equation is shown in Figure 4.8. This output contains information that indicates whether the residuals are correlated and heteroscedastic. In the first table, the second column contains the Durbin-Watson test statistics; the third and fourth columns show the Jarque-Bera normality test statistics and their p-values; the last two columns show F statistics and their p-values for ARCH(1) disturbances. The second table includes F statistics and their p-values for AR(1) to AR(4) disturbances. The results indicate that the residuals are uncorrelated and homoscedastic.

The VARMAX Procedure

Forecasts
Variable	Obs	Time	Forecast	Standard Error	95% Confidence Limits
y1	101	2000	-3.5921	1.1352	-5.8171	-1.3671
	102	2001	-3.0945	1.7091	-6.4443	0.2554
	103	2002	-2.1743	2.1447	-6.3779	2.0292
	104	2003	-1.1139	2.4317	-5.8799	3.6520
	105	2004	-0.1434	2.5874	-5.2146	4.9278
y2	101	2000	-2.0987	1.1910	-4.4330	0.2355
	102	2001	-2.7705	1.4767	-5.6647	0.1237
	103	2002	-2.7572	1.7421	-6.1717	0.6572
	104	2003	-2.2494	2.0193	-6.2071	1.7082
	105	2004	-1.4746	2.2517	-5.8878	2.9386

Figure 4.9: Forecasts

The table in Figure 4.9 gives forecasts and their prediction error covariances.

Chapter Contents
Previous
Next
Top