/* In the PRINTER destination, which can create PCL, PDF and PostScript 
(PS) files, the use of inline style commands will allow control over
justification.  The following inline style command will center the 
text placed on the ODS PDF TEXT= statement in SAS 8.2 and later: */

ods escapechar='^';
ods pdf file='file.pdf' startpage=no;

proc print data=sashelp.class(obs=1);
run;

ods pdf text="^S={just=c} This is my interim title";

proc print data=sashelp.class(obs=1);
run;

ods pdf close;


/*In SAS 9.1, where the TEXT= option is production status, an OUTPUTWIDTH 
specification is necessary for similar logic to work in the RTF destination. */

ods rtf text="^S={outputwidth=100% just=c} My Text";

/* The following PROC TEMPLATE code will also provide formatting control for 
the PRINTER destinations starting in SAS 8.2 and higher and the RTF destination 
in SAS 9.1 and later: */

proc template;
   define style mystyle ;
   parent=styles.printer;
     style UserText from Note / just=c;
   end;
run;


/* Prior to SAS 9.1, the TEXT= option does not adhere to any inline style 
specifications or PROC TEMPLATE instructions for justification in RTF, 
so the raw RTF code below is necessary to force center justification 
in the RTF destination in SAS 8.2: */

ods rtf file="file.rtf" startpage=no;

proc print data=sashelp.class (obs=1); 
run;

ods rtf
  text="{\trowd\trqc\cellx11520\intbl\qc{My Text\cell}{\row}\pard}";

proc print data=sashelp.class (obs=1); 
run;

ods rtf close;