A style attribute, like color, that is defined using a format is not applied to an ACROSS variable's headers in PROC REPORT. The sample code on the Full Code tab demonstrates the problematic syntax.

A hardcoded value for the style attribute is applied correctly.

To circumvent the problem, transpose the data set prior to the PROC REPORT step and control the style attributes for the individual columns. The sample code on the Full Code tab demonstrates this workaround.

Operating System and Release Information

proc format;
   value $gender 'F'='pink' 'M'='lightblue'; 
run;

/* The pink and lightblue color attributes are not applied to the headers for the Sex variable. */
proc report data=sashelp.class; 
   col sex,(weight height); 
   define sex / across style(header)=[background=$gender.] ' '; 
run; 
 

/* Workaround: Transpose the data and use inline formatting to control the color attribute. */
proc transpose data=sashelp.class out=class;
   by name sex;
   var weight height;
run;

proc transpose data=class out=class2;
   by name;
   id sex _name_;
   var col1;
run;

ods escapechar="^";

proc report data=class2;
   col ('^S={background=pink}F' Fweight Fheight) ('^S={background=lightblue}M' Mweight Mheight);
   define Fweight /'Weight';
   define Fheight / 'Height';
   define Mweight / 'Weight';
   define Mheight / 'Height';
run;