options ls=80 ps=55 nocenter nodate nonumber;

*;
*  Begin capturing the output you wish to convert to HTML.
*;

%out2htm(capture=on,
         window=output,
         runmode=b);

*;
*  Obtain summary information and annual payment information.
*;

title 'PROC MORTGAGE Output';

proc mortgage amount=100000 rate=0.085 firstpayment=1996:10
                life=360 yearly;
run;

*;
*  Stop capturing and format the SAS output as HTML, overriding
*  the default settings for TITLES, FOOTNOTES and HEADER line
*  colors. TITLE lines will be Red, FOOTNOTE lines will be Green 
*  and HEADER lines will be Blue.
*;

%out2htm(htmlfile=myfile.html,
         capture=off,
         window=output,
         openmode=replace,
         pagepart=head,
         runmode=b,
         tcolor=red,
         hcolor=blue);

*;
*  Begin capturing more output you wish to convert to HTML.
*;

%out2htm(capture=on,
         window=output,
         runmode=b);

*;
*   Generate raw monthly data for later use.
*;

proc mortgage amount=100000 rate=0.085 firstpayment=1996:10
                life=360 noprint out=monthly;
run;

*;
*  Use SQL to print selected information;
*;

title 'PROC SQL Output';
footnote '(Data generated by PROC MORTGAGE)';

proc sql;
  select *
  from monthly
  where year eq 1996;
quit;

proc format;
  value monthn  1 = 'January'  2 = 'February'  3 = 'March'
                4 = 'April'    5 = 'May'       6 = 'June'
                7 = 'July'     8 = 'August'    9 = 'September'
               10 = 'October' 11 = 'November' 12 = 'December';
run;
                                                
proc datasets nolist;
  modify monthly;
    format month monthn.
           begpri payment int repay endpri comma10.2;
run;

title 'PROC PRINT Output';
footnote '(Data generated by PROC MORTGAGE)';

proc print data=monthly noobs label; 
where year lt 2000;
var year month begpri payment int repay endpri;
sum payment int repay;
run;

*;
*  Stop capturing and format the SAS output as HTML, once again
*  overriding the default settings for TITLES, FOOTNOTES and HEADER 
*  line colors. This time, TITLE lines will be Yellow, FOOTNOTE lines 
*  will be White and HEADER lines will be Teal.
*;

%out2htm(htmlfile=myfile.html,
         capture=off,
         window=output,
         openmode=append,
         pagepart=foot,
         runmode=b,
         tcolor=yellow,
         fcolor=#ffffff,
         hcolor=teal);