%macro power2x2(version, p1=, p2=, n1=, n2=, level=.05, nmin=, nmax=);
%if &version ne %then %put POWER2x2 macro Version 1.0;
data _power_;
  p1=&p1; p2=&p2; level=&level;
  diff=p1-p2;

%if &n1 ne %str() and &n2 ne %str() %then %do;
  n1=&n1; n2=&n2;
  n=n1+n2;
  nmin=n; nmax=n;
%end;
%else %if &nmin ne %str() and &nmax ne %str() %then %do;
  nmin=&nmin; nmax=&nmax;
%end;
  /* select 'nice' range of total sample sizes */
  diforder=10**(max(floor(log10(nmax-nmin+1e-8)),1)-1);
  normlen=(nmax-nmin)/diforder;
  step=diforder*((normlen<=20)+2*(20<normlen<=40)+5*(40<normlen<=100));
  do n=nmin, nmin+step-mod(nmin+step,step) to nmax by step, nmax;
   %if &nmin ne %str() and &nmax ne %str() %then %do;
     n1=n/2; n2=n/2;
   %end;
     /* power and beta computation */
     ph0=(n1*p1+n2*p2)/(n1+n2);
     stdh0=sqrt(ph0*(1-ph0)*(1/n1+1/n2));
     stdha=sqrt(p1*(1-p1)/n1+p2*(1-p2)/n2);
     Power=1-probnorm(-probit(level/2)*stdh0/stdha-diff/stdha) +
             probnorm( probit(level/2)*stdh0/stdha-diff/stdha);
     Beta=1-power;
     output;
     if n=round(nmax) then stop;
  end;
run;

proc print noobs split='/';
  var n power beta;
  label n="Total/Sample/Size";
  title  "Power for comparing two independent proportions";
  title2 "p1=&p1, p2=&p2, level=&level";
  run;
title;
%mend;