FONTSCALE is used only to tell ODS PRINTER code how
to scale fonts that are specified using the old-fashioned HTML font
size numbers; because the SAS 8 and later ODS PRINTER code ships with a style that uses
"real" font sizes (e.g., 11pt), FONTSCALE is ignored. In actual point of
fact, it was an error
to let it get into the SAS 8 documentation.
The way to change font sizes is via the ODS style. Two main
parameters control the overall size of typical ODS PRINTER
output: the font size and the table CELLPADDING. (The cell
padding is the space on the top, bottom, right, and left of the cells,
between the actual cell text and the rules.)
For example, here is some code to shrink the output to about 80% of the
usual size:
proc template;
define style Styles.smaller;
parent = styles.Printer;
replace fonts / /* Reduce all sizes by 2pt */
'TitleFont2' = ("Times",10pt,Bold Italic)
'TitleFont' = ("Times",11pt,Bold Italic)
'StrongFont' = ("Times",8pt,Bold)
'EmphasisFont' = ("Times",8pt,Italic)
'FixedEmphasisFont' = ("Courier New, Courier",7pt,Italic)
'FixedStrongFont' = ("Courier New, Courier",7pt,Bold)
'FixedHeadingFont' = ("Courier New, Courier",7pt,Bold)
'BatchFixedFont' = ("SAS Monospace, Courier New, Courier",5pt)
'FixedFont' = ("Courier New, Courier",7pt)
'headingEmphasisFont' = ("Times",9pt,Bold Italic)
'headingFont' = ("Times",9pt,Bold)
'docFont' = ("Times",8pt);
style Table from Output /
rules = ALL
cellpadding = 2pt /* Reduced from 4pt to 2pt */
cellspacing = 0.25pt
borderwidth = 0.75pt;
end;
run;
ods pdf file="my-file.pdf" style=smaller;
proc print data=sashelp.class; run;
ods pdf close;
For code showing how to do this in the RTF destination, see
FAQ 4503.
And for information on how to do this in the HTML destination, see FAQ 3272.
Operating System and Release Information
*
For software releases that are not yet generally available, the Fixed
Release is the software release in which the problem is planned to be
fixed.
