In the following examples, assume you are running Release 6.08 of the SAS System at TS405 level or higher. The examples use the CC=NONE option as appropriate.

If you are running Release 6.08 on OpenVMS/VAX at the TS levels below TS405, you can use the examples but remove the CC=NONE from the LIBNAME statement. You will need to remove the record attribute of carriage control carriage return before moving the transport file to the destination operating system. More information is available for details on how to remove this attribute. (Create a link here back to answers with convert/fdl=)

Example 1:

Here we create a transport file during a SAS DATA step. The XPORT engine's special set of input/output routines are used to create the transport file during the DATA step. The CC=NONE option in the LIBNAME statement instructs SAS to create the transport file with the record attribute of NONE. The transport file contains all the variables and observations from the permanently stored SAS data set USERS found in the directory referenced by the libref SASDATA.

   libname sasdata '[username.tech1]';
   libname gone xport '[username.tech1]tranfile.dat' cc=none;
   data gone.account;
     set sasdata.users;
     if code='00003' then status='ALERT';
     else status='REG';
   run;

Example 2:

Here we create a transport file with all the SAS data sets in the directory except the EMPLOYEE and CONSULT SAS data sets.

   libname sasdata '[username.tech1]';
   libname gone xport '[username.tech1]tranfile.dat' cc=none;
   proc copy in=sasdata out=gone;
     exclude employee consult;
   run;

Example 3:

This example is a modification of Example 1 above. In this example, we use PROC CPORT to create the transport file. Note: This transport file can only be processed by a PROC CIMPORT at the same or higher release.

   libname sasdata '[username.tech1]';
   filename gonefile '[username.tech1]portfile.dat' cc=none;
   data work.account;
     set sasdata.users;
     if code='00003' then status='ALERT';
     else status='REG';
   run;
   proc cport data=work.account file=gonefile;
   run;

Example 4:

Here we copy all the SAS data sets in the directory referenced by the libref SASDATA into the transport file.

   libname sasdata '[username.tech1]';
   filename gonefile '[username.tech1]portfile.dat' cc=none;
   proc cport library=sasdata memtype=data file=gonefile;
   run;

Operating System and Release Information