• Print |
• E-mail  |
• Bookmark

The label for the special format range OTHER may display in the RBREAK
summary line in SAS 8.1 and 8.2. The problem occurs when using a
character variable defined as a DISPLAY variable and no GROUP or ORDER
variables appear to its left in the report.

If you are using a character format which does not include a missing
value in a range specification, adding a null format range:  ' '=' '
to the format will circumvent the problem. If a missing value is
included in a range specification, you can circumvent the problem with a
CALL DEFINE to assign a format for the summary line.

   proc format;
     value $test
          'X'='a long name to display 1'
          'Y'='a long name to display 2'
        other='unknown value';
       /* adding this range and label combination to the VALUE
          statement above can circumvent the problem in
          some cases:  ' '=' ' ; */

     value $blank  other=' ';
   run;

   data test;
     input name $ value;
   cards;
   X 124.6
   Y 111.1
   Z 432.4
   ;
   run;

   /* this will demonstrate the problem  */
   proc report data=test nowd headline headskip;
      column name value;
      define name  / display format=$test.;
      define value / sum     format=8.1;
      rbreak after  / skip dol summarize;
   run;


   /* this will circumvent the problem   */
   proc report data=test nowd headline headskip;
      column name value;
      define name  / display format=$test. 'Name';
      define value / sum     format=8.2    'Value';

      compute name;
         if upcase(_break_)='_RBREAK_' then
            call define(_col_,'format','$blank.');
      endcomp;

      rbreak after  / skip dol summarize;
   run;


A Technical Support hot fix for Release 8.2 (TS2M0) for this
issue is available at:

http://www.sas.com/techsup/download/hotfix/82_sbcs_prod_list.html#010051

For customers running SAS with Asian Language Support (DBCS), this
hot fix should be downloaded from:

http://www.sas.com/techsup/download/hotfix/82_dbcs_prod_list.html#010051

Operating System and Release Information

A fix for Release 8.2 (TS2M0) for this issue is available at:

A fix for Release 8.2 (TS2M0) with Asian Language Support (DBCS) for this issue is available at: