Example 3 for PROC MULTTEST
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: MULTEX3 */
/* TITLE: Example 3 for PROC MULTTEST */
/* PRODUCT: STAT */
/* SYSTEM: ALL */
/* KEYS: multiple test, */
/* multiple comparisons */
/* PROCS: MULTTEST */
/* DATA: */
/* */
/* SUPPORT: Bob Derr */
/* REF: SAS/STAT User's Guide, PROC MULTTEST chapter */
/* MISC: */
/* */
/****************************************************************/
/*----------------------------------------------------------------
Each observation represents an animal. S1, S2 and S3 are three
tumor types with 0=no tumor, 1=nonlethal tumor, and 2=lethal tumor.
Dose is the dosage, T is the time of death of the animal, B is a
strata variable constructed from T.
----------------------------------------------------------------*/
title 'Peto Mortality-Prevalence Test';
data a;
input S1-S3 T Dose @@;
if T<=90 then B=1; else B=2;
datalines;
0 0 0 104 0 2 0 1 80 0 0 0 1 104 0
0 0 0 104 0 0 2 0 100 0 1 0 0 104 0
2 0 0 85 1 2 1 0 60 1 0 1 0 89 1
2 0 1 96 1 0 0 0 96 1 2 0 1 99 1
2 1 1 60 2 2 0 0 50 2 2 0 1 80 2
0 0 2 98 2 0 0 1 99 2 2 1 1 50 2
;
proc multtest data=a notables out=p stepsid;
test peto(S1-S3 / permutation=20 time=T uppertailed);
class Dose;
strata B;
contrast 'mort-prev' 0 1 2;
run;
proc print data=p;
run;
