MCF Plot for Defrost Control Data

 /****************************************************************/
 /*          S A S   S A M P L E   L I B R A R Y                 */
 /*                                                              */
 /*    NAME: RELMCF3                                             */
 /*   TITLE: MCF Plot for Defrost Control Data                   */
 /* PRODUCT: QC                                                  */
 /*  SYSTEM: ALL                                                 */
 /*    KEYS:                                                     */
 /*   PROCS: RELIABILITY                                         */
 /*    DATA: Nelson (2002)                                       */
 /*     REF: SAS/QC Software: The RELIABILITY Procedure          */
 /*                                                              */
 /*                                                              */
 /****************************************************************/
 options nodate nostimer nonumber source2 ls=76 ps=80;

/*** Nelson, W. (2002), Problem 5.2, Recurrent Events Data  ***/
/*** Analysis for Product Repairs, Disease Recurrences,     ***/
/*** and Other Applications,  ASA-SIAM Series on Statistics ***/
/*** and Applied Probability.                               ***/

data Defrost;
t1=t2;
t2+1;
label t1 = 'Months';
   input r n @@;
   datalines;
83 22914  35 22914  23 22914  15 22914  22 22914
16 22914  13 22911  12 22875  15 22851  15 22822
24 22785  12 22745   7  2704  11 2690   15 2673
6  2660    8  2632   9  2610   9  2583   5  2519
6  2425    6  2306   6  2188   5  2050   7  862
5  845     5  817    6  718    3  590
;
run;

data d2 ( keep = n rename = ( n = n1 )  );
   set defrost;
   if _n_ > 1;
run;

data d3;
  n1 = 0;
run;

data d2 ;
   set d2 d3;
run;

data defrost ( keep =  t1 t2 r c
               rename = ( t1 = Lower t2 = Upper
                          r = Recurrences c = Censored ) );
   set defrost;
   set d2;
   c = n - n1;
run;

proc reliability data=Defrost;
   mcfplot ( interval    = Lower Upper
             recurrences = Recurrences
             censor      = Censored ) / plotsymbol = X
                                        plotcolor = blue
                                        vaxis = 0 to .12 by .02
                                        ;

run;