Pareto Analysis Based on Cost
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: PAREX8 */
/* TITLE: Pareto Analysis Based on Cost */
/* PRODUCT: QC */
/* SYSTEM: ALL */
/* KEYS: Pareto Charts */
/* PROCS: PARETO */
/* DATA: */
/* */
/* SUPPORT: saswgr */
/* REF: PROC PARETO, Example 8 */
/* MISC: */
/* */
/****************************************************************/
proc format;
value procfmt 1 = 'Process A'
2 = 'Process B';
value dayfmt 1 = 'Monday'
2 = 'Tuesday'
3 = 'Wednesday'
4 = 'Thursday'
5 = 'Friday';
run;
data Failure5;
length Cause $16;
format Process procfmt. Day dayfmt.;
label Cause = 'Cause of Failure'
Process = 'Cleaning Method'
Day = 'Day of Manufacture';
input Process Day Cause $16. Counts @@;
datalines;
1 1 Contamination 15 1 1 Corrosion 2
1 1 Doping 1 1 1 Metallization 2
1 1 Miscellaneous 3 1 1 Oxide Defect 8
1 1 Silicon Defect 1 1 2 Contamination 16
1 2 Corrosion 3 1 2 Doping 1
1 2 Metallization 3 1 2 Miscellaneous 1
1 2 Oxide Defect 9 1 2 Silicon Defect 2
1 3 Contamination 20 1 3 Corrosion 1
1 3 Doping 1 1 3 Metallization 0
1 3 Miscellaneous 3 1 3 Oxide Defect 7
1 3 Silicon Defect 2 1 4 Contamination 12
1 4 Corrosion 1 1 4 Doping 1
1 4 Metallization 0 1 4 Miscellaneous 0
1 4 Oxide Defect 10 1 4 Silicon Defect 1
1 5 Contamination 23 1 5 Corrosion 1
1 5 Doping 1 1 5 Metallization 0
1 5 Miscellaneous 1 1 5 Oxide Defect 8
1 5 Silicon Defect 2 2 1 Contamination 8
2 1 Corrosion 2 2 1 Doping 1
2 1 Metallization 4 2 1 Miscellaneous 2
2 1 Oxide Defect 10 2 1 Silicon Defect 3
2 2 Contamination 9 2 2 Corrosion 0
2 2 Doping 1 2 2 Metallization 2
2 2 Miscellaneous 4 2 2 Oxide Defect 9
2 2 Silicon Defect 2 2 3 Contamination 4
2 3 Corrosion 1 2 3 Doping 1
2 3 Metallization 0 2 3 Miscellaneous 0
2 3 Oxide Defect 10 2 3 Silicon Defect 1
2 4 Contamination 2 2 4 Corrosion 2
2 4 Doping 1 2 4 Metallization 0
2 4 Miscellaneous 3 2 4 Oxide Defect 7
2 4 Silicon Defect 1 2 5 Contamination 1
2 5 Corrosion 3 2 5 Doping 1
2 5 Metallization 0 2 5 Miscellaneous 1
2 5 Oxide Defect 8 2 5 Silicon Defect 2
;
data Failure5;
length Analysis $ 16;
label Analysis = 'Basis for Analysis';
set Failure5;
Analysis = 'Cost';
if Cause = 'Contamination' then Cost = 3.0;
else if Cause = 'Metallization' then Cost = 8.5;
else if Cause = 'Oxide Defect' then Cost = 9.5;
else if Cause = 'Corrosion' then Cost = 2.5;
else if Cause = 'Doping' then Cost = 3.6;
else if Cause = 'Silicon Defect' then Cost = 3.4;
else Cost = 1.0;
output;
Analysis = 'Frequency';
Cost = 1.0;
output;
run;
ods graphics off;
goptions vsize=4.25 in htext=2.8 pct htitle=3.2 pct;
title 'Pareto Analysis By Cost and Frequency';
proc pareto data=Failure5;
vbar Cause / class = ( Analysis )
freq = Counts
weight = Cost
barlabel = value
out = Summary
intertile = 1.0;
run;
proc print data=Summary;
run;
