Breadwrapper Stock: Response-Surface Study
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: ADXEG4 */
/* TITLE: Breadwrapper Stock: Response-Surface Study */
/* PRODUCT: QC */
/* SYSTEM: ALL */
/* KEYS: Design of Experiments,Factorial Designs */
/* PROCS: */
/* DATA: */
/* REF: Myers, R.H. (1976). Response Surface Methodology. */
/* pp. 78-84. */
/* MISC: ADX Macros are stored in the AUTOCALL library */
/* */
/* */
/* Myers (1976) uses a central composite design to test the seal*/
/* strength in grams per inch of a breadwrapper stock. The */
/* three factors that are examined are, */
/* */
/* * the sealing temperature (STMP), */
/* * the cooling temperature (CTMP), and */
/* * the percentage of the polyethylene additive (POLY) */
/* that is used. */
/* */
/****************************************************************/
/*--------------------------------------------------------------*/
/* EXAMPLE 4: A CENTRAL COMPOSITE DESIGN FOR A BREADWRAPPER */
/* STUDY. */
/* SOURCE: MYERS (1976). */
/*--------------------------------------------------------------*/
/*
/ For this example, we need only the central composite design
/ macros:
/ if we haven't already included them, we do so now.
/---------------------------------------------------------------*/
%adxgen;
%adxff;
%adxcc;
%adxinit /* Initialize ADX environment. */
/*
/ First, find out which designs are available for the three
/ treatment factors.
/---------------------------------------------------------------*/
%adxpcc(3)
/*
/ Myers chooses an 8-run design having 6 center points and the
/ axial point value of 1.6818. NOTE: Although 9 center points
/ are required to achieve an orthogonal design, you may specify
/ only 6 center points.
/---------------------------------------------------------------*/
%adxccd(bread,3,8,6,1.6818)
/*
/ Decode the data.
/---------------------------------------------------------------*/
%adxdcode(bread,t1 stmp 225 285 /t2 ctmp 46 64 /t3 poly 0.5 1.7)
/*
/ Normally we would also make up a randomized data collection
/ form to be submitted to the experimenter using the command
/ %adxrprt(bread,sealstr)
/ Assuming that this was done and that the data has been
/ collected, the results, which can be found in Myers (1976),
/ page 79, are then added to this data set.
/---------------------------------------------------------------*/
data bread;
set bread;
input @@ sealstr;
cards;
6.6 9.2 7.9 10.4 6.9 6.8 6.1 7.3 10.1 9.9
12.2 9.7 9.7 9.6 5.0 9.8 6.3 6.9 8.6 4.0
;
run;
/*
/ Analyze this data using PROC RSREG.
/---------------------------------------------------------------*/
proc rsreg;
model sealstr = stmp ctmp poly;
run;
/*--------------------------------------------------------------*/
/* */
/* We can conclude from the output that the significant effects */
/* come from the following variables: the main effects of the */
/* sealing temperature and the polyethylene additive, as well */
/* as all three of the quadratic variables. The stationary */
/* point, which is a maximum, is given along with the estimated */
/* response at this point. */
/* */
/*--------------------------------------------------------------*/
