Scheduling a Hospital Move (netdre19)
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: NETDRE19 */
/* TITLE: Scheduling a Hospital Move (netdre19) */
/* PRODUCT: OR */
/* SYSTEM: ALL */
/* KEYS: NETDRAW */
/* PROCS: CPM, NETDRAW */
/* DATA: */
/* */
/* SUPPORT: UPDATE: */
/* REF: Activity Networks by Salah E. Elmaghraby */
/* MISC: */
/* */
/****************************************************************/
DATA MOVE;
INPUT ACTIVITY $ 1-44 ID 45-46 DURATION 48-50
(SUCESS1-SUCESS7) (+1 2.);
DATALINES;
Meet with department heads 01 002 09 11 12 13 14 15 16
Consult with director 02 001 03
Tag furniture to be moved 03 001 09 11 12 13 14 15 16
Appoint move advisory committee 04 008 05
Establish move admission policies 05 010 06 19 21
Revise admission policies 06 010 32 40 41 42 43 44 45
Modify disaster plans for new hospital 07 010 31
Plan prel. public relations activities 08 010 33 46 47 48 49
Meet with city traffic engineer 09 005 19 21
Have prel. meeting with police officials 10 005 17
Consult with department heads 11 015 19 21
Negotiate contract on specialized equip 12 020 19 21
Negotiate prel. contract on ambulance buses 13 016 19 21
Develop preliminary move plan 14 020 19 21
Develop prel. contacts with other hospitals 15 017 19 21
Identify security needs for new/old hospital16 012 19 21
Develop police move assistance plan 17 170 57 58 59
Plan employee orientation at new hospital 18 055 54
Develop final move plan 19 020 20 23 24 29 63
Consult building coordinator and contractor 20 020 62
Establish packing material supply center 21 020 22
Stock packing materials center 22 025 30
Prepare final move tags 23 028 28
Arrange shuttle bus between hospitals 24 054 35 37 38 39 40 41 42
24 054 43 44 45 52
Finalize contacts with outside firms 25 033 35 37 38 39 40 41 42
25 033 43 44 45 52
Publish plans 26 003 27 34
Modify plans 27 028 35 37 38 39 40 41 42
27 028 43 44 45 52
Tag furniture & equipment 28 033 35 37 38 39 40 41 42
28 033 43 44 45 52
Plan security open houses & old hospital 29 038 35 37 38 39 40 41 42
29 038 43 44 45 52
Plan premove activity and equipment 30 040 35 37 38 39 40 41 42
30 040 43 44 45 52
Publish new disaster plan 31 068 55 56
Implement premove admissions policies 32 028 55 56
Hold reception for press Lay Board as hosts 33 001 20 23 24 29 63
Construct cleaning station 34 022 37
Establish parking plans 35 017 36
Implement street & parking plans 36 028 64
Clean equipment on arrival 37 037 64
Clean in new hospital 38 028 55 56
Serve lunches in new hospital 39 018 55 56
Make final arrangements with other hospitals40 030 55 56
Finalize ambulance arrangements 41 030 55 56
Contact army regarding ambulance buses 42 030 55 56
Move equipment, furnishings, and functions 43 056 64
Prepare for patient move 44 035 55 56
Operate shuttle bus 45 028 57 58 59
Prepare & distribute move newsletter 46 085 55 56
Plan open houses 47 060 50
Prepare move fact book for employees 48 052 50
Plan dedication of new hospital 49 075 53
Train guides (fuild volunteers) 50 010 51
Hold open house 51 015 55 56
Provide for security as required 52 015 55 56
Plan dedication 53 010 55 56
Hold employee orientations at new hospital 54 040 55 56
Arrange for public relations to assist press55 001 57 58 59
Prepare for patient move 56 001 58
Implement post-move admissions policies 57 008 64
Provide for security at old hospital 58 012 64
Move remaining equipment 59 010 60
Prepare for sale of surplus material 60 002 61
Dispose of unsellable items 61 002 64
Decide on move day 62 010 25 26
Publish instructions 63 020 30
-----MOVE----- 64 000
;
proc cpm data=move out=sched date='1nov88'd;
act id;
dur duration;
succ sucess1-sucess7;
id activity;
run;
goptions border;
pattern1 v=e c=green;
pattern2 v=e c=red;
title h=1.5 j=l 'Project: Hospital Move';
proc netdraw data=sched graphics;
actnet / act=id succ=(sucess1-sucess7)
id=(activity) dur=duration separatearcs
nodefid nolabel
compress
carcs=blue
ccritarcs=red
noarrowfill;
format activity $char10.;
run;
