Non Standard Precedence Relationships (netdre06)

/****************************************************************/
/*          S A S   S A M P L E   L I B R A R Y                 */
/*                                                              */
/*    NAME: NETDRE06                                            */
/*   TITLE: Non Standard Precedence Relationships (netdre06)    */
/* PRODUCT: OR                                                  */
/*  SYSTEM: ALL                                                 */
/*    KEYS: NETDRAW                                             */
/*   PROCS: CPM, NETDRAW                                        */
/*    DATA:                                                     */
/*                                                              */
/* SUPPORT:                             UPDATE:                 */
/*     REF: Example 6 from the NETDRAW Chapter (PM User's Guide)*/
/*    MISC:                                                     */
/*                                                              */
/****************************************************************/

 /* Activity-on-Node representation of the project with lags */
data widglag;
   input task $ 1-12 days succ $ 19-30 lagdur $ 33-37;
   datalines;
Approve Plan   5  Drawings
Approve Plan   5  Study Market
Approve Plan   5  Write Specs
Drawings      10  Prototype
Study Market   5  Mkt. Strat.
Write Specs    5  Prototype
Prototype     15  Materials     ss_9
Prototype     15  Facility      ss_9
Mkt. Strat.   10  Test Market
Mkt. Strat.   10  Marketing
Materials     10  Init. Prod.
Facility      10  Init. Prod.   fs_2
Init. Prod.   10  Test Market
Init. Prod.   10  Marketing
Init. Prod.   10  Evaluate
Evaluate      10  Changes       ss_6
Test Market   15  Changes       ff_3
Changes        5  Production
Production     0
Marketing      0
;

title 'Widget Manufacture';
title2 'Network Data Set';
proc print;
   run;

pattern1 v=e c=green;

title h=3 'Widget Manufacture';
title2 h=2 'Nonstandard Precedence Constraints';

proc netdraw graphics data=widglag;
   actnet / act=task
            succ=succ
            lag=lagdur
            pcompress
            htext=3 boxht=3 arrowhead=2
            xbetween=7 ybetween=9
            centerid
            separatearcs;
   run;