Spanning Multiple Pages (netdre03)

/****************************************************************/
/*          S A S   S A M P L E   L I B R A R Y                 */
/*                                                              */
/*    NAME: NETDRE03                                            */
/*   TITLE: Spanning Multiple Pages (netdre03)                  */
/* PRODUCT: OR                                                  */
/*  SYSTEM: ALL                                                 */
/*    KEYS: NETDRAW                                             */
/*   PROCS: CPM, NETDRAW                                        */
/*    DATA:                                                     */
/*                                                              */
/* SUPPORT:                             UPDATE:                 */
/*     REF: Example 3 from the NETDRAW Chapter (PM User's Guide)*/
/*    MISC:                                                     */
/*                                                              */
/****************************************************************/

 /* Activity-on-Node representation of the project */
data widget;
   format task $12. succ1-succ3 $12.;
   input task & days succ1 & succ2 & succ3 & ;
   datalines;
Approve Plan   5  Drawings      Study Market  Write Specs
Drawings      10  Prototype     .             .
Study Market   5  Mkt. Strat.   .             .
Write Specs    5  Prototype     .             .
Prototype     15  Materials     Facility      .
Mkt. Strat.   10  Test Market   Marketing     .
Materials     10  Init. Prod.   .             .
Facility      10  Init. Prod.   .             .
Init. Prod.   10  Test Market   Marketing     Evaluate
Evaluate      10  Changes       .             .
Test Market   15  Changes       .             .
Changes        5  Production    .             .
Production     0  .             .             .
Marketing      0  .             .             .
;

proc cpm data=widget out=sched
         date='1dec03'd;
   activity task;
   successor succ1 succ2 succ3;
   duration days;
   run;

goptions hpos=80 vpos=50 border;
pattern1 c=ltgray v=s;
pattern2 c=ltgray v=s;

title c=blue j=l h=1.5 ' Project: Widget Manufacture';
title2 c=blue j=l h=1.5 ' Schedule Information';
footnote c=blue j=r h=1.5 'Spanning Multiple Pages ';
proc netdraw data=sched graphics;
   actnet / act=task
            succ=(succ1 succ2 succ3)
            dur = days
            coutline=blue
            ccritout=red
            carcs=blue
            ccritarcs=red
            ctext=blue
            lwidth=1
            lwcrit=2
            separatearcs;
   run;