ODS Graphics Template Modification

Reverting to the Default Templates

Customized templates are stored in Sasuser.Templat or in some other template store that you create. The templates that SAS supplies are in the read-only template store Sashelp.Tmplmst. If you modify any of the supplied templates and you want to use the original default templates, you can change your template search path as follows:

ods path sashelp.tmplmst(read) sasuser.templat(update);

This way the default templates are found first. Alternatively, you can save all your customized templates in a user-defined template store (for example Mylib.Mystore). To access these templates, you submit the following statement before running your analysis:

libname mylib '.';
ods path mylib.mystore(update) sashelp.tmplmst(read);

When you are done, you can reset the default template search path as follows:

ods path reset;

This restores the template search path to its original state (sasuser.templat(update) sashelp.tmplmst(read)). You can also save your customized template as part of your SAS program. When you are done, you can delete your customized template from the Sasuser.Templat template store, as in the following statements:

proc template;
   delete Stat.REG.Graphics.ResidualPlot / store=sasuser.templat;

The option STORE=SASUSER.TEMPLAT is not required. However, if you have administrator privileges on your computer, this option helps you ensure that you do not accidentally delete templates from Sashelp.Tmplmst.

The following note is printed in the SAS log:

   NOTE: 'Stat.REG.Graphics.ResidualPlot' has been deleted from: SASUSER.TEMPLAT

You can run the following step to delete the entire Sasuser.Templat store of customized templates:

ods path sashelp.tmplmst(read);
proc datasets library=sasuser nolist;
   delete templat(memtype=itemstor);
ods path sasuser.templat(update) sashelp.tmplmst(read);