Introduction to Structural Equation Modeling with Latent Variables


Fitting LISREL Models by the LISMOD Modeling Language

The model described in the section Career Aspiration: Analysis 3 provides a good example of the LISREL model. In PROC CALIS, the LISREL model specifications are supported by a matrix-based language called LISMOD (LISREL model). In this section, the path diagram in Figure 17.47 is specified by the LISMOD modeling language of PROC CALIS. See the section Career Aspiration: Analysis 3 for detailed descriptions of the model.

In order to understand the LISMOD modeling language of PROC CALIS, some basic understanding of the LISREL model is necessary. In a LISREL model, variables are classified into four distinct classes:

  • $\xi $ is a vector of exogenous (independent) latent variables in the model. They are specified in XI= variable list in the LISMOD statement.

  • $\eta $ is a vector of endogenous (dependent) latent variables in the model. They are specified in ETA= variable list in the LISMOD statement.

  • x is a vector of observed indicator variables for $\xi $ in the model. They are specified in XVAR= variable list in the LISMOD statement.

  • y is a vector of observed indicator variables for $\eta $ in the model. They are specified in YVAR= variable list in the LISMOD statement.

For detailed descriptions of the LISMOD modeling language, see the LISMOD statement and the section The LISMOD Model and Submodels in Chapter 29: The CALIS Procedure. To successfully set up a LISMOD model in PROC CALIS, you first need to recognize these classes of variables in your model. For the path diagram in Figure 17.47, it is not difficult to see the following:

  • $\xi $ is the vector of the intelligence and environmental factors: f_rpa, f_riq, f_rses, f_fses, f_fiq, and f_fpa. These variables are exogenous because no single-headed arrows point to them.

  • $\eta $ is the vector of the ambition factors: R_Amb, and F_Amb. They are endogenous because each of them has at least one single-headed arrow pointing to it.

  • x is the vector of the observed indicator variables for the intelligence and environmental factors $\xi $. These indicators are rpa, riq, rses, fses, fiq, and fpa.

  • y is the vector of observed indicator variables for the ambition factors $\eta $. These indicators are rea, roa, foa, and fea.

In LISMOD, you do not need to define error terms explicitly as latent variables. The parameters in LISMOD are defined as entries in various model matrices. The following statements specify the LISMOD model for the diagram in Figure 17.47:

proc calis data=aspire nobs=329;
   lismod
      xi   = f_rpa f_riq f_rses f_fses f_fiq f_fpa,
      eta  = R_Amb F_Amb,
      xvar = rpa riq rses fses fiq fpa,
      yvar = rea roa foa fea;

   /* measurement model for aspiration */
   matrix _lambday_ [1,1], [2,1] = 1.0, [3,2] = 1.0, [4,2];
   matrix _thetay_  [4,1], [3,2];

   /* measurement model for intelligence and environment */
   matrix _lambdax_ [1,1] = 0.837 0.894 0.949 0.949 0.894 0.837;

   /* structural model of influences */
   matrix _beta_ [2,1],[1,2];
   matrix _gamma_ [1,1 to 4], [2,3 to 6];

   /* Covariances among Eta-variables */
   matrix _psi_ [2,1];

   /* Fixed variances for Xi-variables */
   matrix _phi_ [1,1] = 6 * 1.0;
run;

The LISMOD statement invokes the LISMOD modeling language of PROC CALIS. In the LISMOD statement, you list the four classes of variables in the model in the XI=, ETA=, XVAR=, and YVAR= variable lists, respectively. After you define the four classes of variables, you use several MATRIX statements to specify the model matrices and the parameters in the model.

Basically, there are three model components in the LISMOD specification: two measurement models and one structural model. The first measurement model specifies the functional relationships between observed variables y (YVAR= variables) and the endogenous (dependent) latent factors $\eta $ (ETA= variables). The second measurement model specifies the functional relationships between observed variables x and (XVAR= variables) and the exogenous (independent) latent factors $\xi $ (XI= variables). The structural model specifies the relationships between the endogenous and exogenous latent variables $\eta $ and $\xi $. To facilitate the discussion of these model components and the corresponding LISMOD model specification, some initial model output from PROC CALIS are shown.