The Default Template Libraries and the ODS PATH

The default table, graph, and style templates that SAS provides are stored in the library SASHELP.Tmplmst. By default, if you modify a template, it is stored in the library SASUSER.Templat. By default, ODS searches SASUSER.Templat for templates, and then it searches SASHELP.Tmplmst if it does not find the requested template in SASUSER.Templat. You can see the list of template libraries by submitting the following statement:

   ods path show;

Here are the results:

   Current ODS PATH list is:

   1. SASUSER.TEMPLAT(UPDATE)
   2. SASHELP.TMPLMST(READ)

You can change the ODS PATH to add template libraries that you create or change the order that the libraries are searched. This is discussed in detail in the sections Saving Customized Templates, Using Customized Templates, and Reverting to the Default Templates. However, this section discusses the default template libraries that you use when you have not modified the ODS path. SAS always finds the templates it provides in SASHELP.Tmplmst if you did not store a modified template in SASUSER.Templat. Otherwise, it finds and uses your modified template in SASUSER.Templat. You can see a list of all of the templates that you have modified as follows:

   proc template;
      list / store=sasuser.templat;
   run;

You can delete any template that you modified (so that ODS finds the default template that SAS supplied) by specifying it on a DELETE statement, as in the following example:

   proc template;
      delete Stat.REG.Graphics.ResidualPlot;
   run;

ODS never deletes the template in SASHELP.Tmplmst, so you can safely run the preceding step, even if the template you specify does not exist in SASUSER.Templat. You can run the following step to delete the entire SASUSER.Templat library of customized templates so that ODS uses only the SAS supplied templates:

   ods path sashelp.tmplmst(read);
   proc datasets library=sasuser;
      delete templat(memtype=itemstor);
   run;
   ods path sasuser.templat(update) sashelp.tmplmst(read);

It is good practice to delete templates that you have customized when you are done with them, so that they are not unexpectedly used later. See the section Reverting to the Default Templates for more information.