Constructed Effects and the EFFECT Statement

The experimental EFFECT statement in SAS 9.2 is supported by the GLIMMIX, GLMSELECT, and QUANTREG procedures. The EFFECT statement enables you to construct special collections of columns for design matrices. These collections are referred to as constructed effects to distinguish them from the usual model effects formed from continuous or classification variables, as discussed in the section GLM Parameterization of Classification Variables and Effects. For example, the terms A, B, x, A*x, A*B, and sub in the following statements define fixed, random, and subject effects of the usual type in a mixed model, respectively:

   proc glimmix;
      class A B sub;
      model y = A B x A*x;
      random A*B / subject=sub;
   run;

A constructed effect, on the other hand, is assigned through the EFFECT statement. For example, in the following program, the EFFECT statement defines a constructed effect named spl:

   proc glimmix;
      class A B SUB;
      effect spl = spline(x);
      model y = A B A*spl;
      random A*B / subject=sub;
   run;

The columns of spl are formed from the data set variable x as a cubic B-spline basis with three equally spaced interior knots.

Each constructed effect corresponds to a collection of columns that are referred to by using the name you supply. You can specify multiple EFFECT statements, and all EFFECT statements must precede the MODEL statement.

The general syntax for the EFFECT statement with effect-specification is

EFFECT effect-name = effect-type (var-list < / effect-options >) ;

The name of the effect is specified after the EFFECT keyword. This name can appear in only one EFFECT statement and cannot be the name of a variable in the input data set. The effect type is specified after an equal sign, followed by a list of variables used in constructing the effect within parentheses. Effect-type specific options can be specified after a slash (/) following the variable list.

The following effect-types are available and subsequently discussed.

COLLECTION

is a collection effect defining one or more variables as a single effect with multiple degrees of freedom. The variables in a collection are considered as a unit for estimation and inference.

MULTIMEMBER|MM

is a multimember classification effect whose levels are determined by one or more variables that appear in a CLASS statement.

POLYNOMIAL|POLY

is a multivariate polynomial effect in the specified numeric variables.

SPLINE

is a regression spline effect whose columns are univariate spline expansions of one or more variables. A spline expansion replaces the original variable with an expanded or larger set of new variables.