Refreshing SPD Server Parameter and LIBNAME Files

You can use PROC SPDO to dynamically refresh SPD Server parameter and LIBNAME files. If you make changes to your spdsserv.parm file or to your libnames.parm environment file for SPD Server, you can use the REFRESH command to avoid restarting the server. Submitting the REFRESH command refreshes the specified SPD Server file without restarting the server.

When you submit the REFRESH command, SPD Server refreshes the operating parameter file.

The syntax for the REFRESH command to refresh the libnames.parm file is:

REFRESH DOMAINS

The syntax for the REFRESH command to refresh the spdsserv.parm file is:

REFRESH PARMS

Each REFRESH operation completely refreshes and replaces the contents of the previous libnames.parm file or the spdsserv.parm file in the SPD Server environment.

Add a new LIBNAME domain to your current libnames.parm file and use it without restarting the server:

LIBNAME spds44 sasspds 'spds44'
        server=estore.5180
        user='admin'
        password='spds123'
        aclspecial=YES
        prompt=YES;

PROC SPDO library=spds44;
  SET acluser admin;
  REFRESH PARMS;
  REFRESH DOMAINS;
quit;

Here is a more detailed example:

     /* Domain reftest is a pre-existing domain.  */
     /* Add domain reftest2 to libnames.parm and  */
     /* specify owner=admin                       */

        LIBNAME=tmp pathname=c:\temp;
        LIBNAME=formats pathname=c:\data\formats;
        LIBNAME=reftest pathname=c:\data\reftest
          owner=admin;
        LIBNAME=reftest2 pathname=c:\data\reftest2
          owner=admin;

     /* Run refresh job using admin with ACLSPECIAL */
     /* The SPD Server user must have ACLSPECIAL    */
     /* privileges to refresh domains.              */

        LIBNAME reftest sasspds 'reftest'
          server=d8488.5180
          user='admin'
          password='spds123'
          aclspecial=YES;

        PROC SPDO library=reftest;
          SET acluser admin;
          REFRESH DOMAINS;
        quit;

     /* Domains that have an owner= option such as  */
     /* reftest2 (owner=admin) must be reconnected  */
     /* to the domain again.                        */

        LIBNAME reftest2 sasspds 'reftest2'
          server=d8488.5180
          user='admin'
          password='spds123';