The ANOM Procedure


Positioning the Inset Using Coordinates

Note: See Positioning the Inset Using Coordinates on an ANOM Chart in the SAS/QC Sample Library.

When you produce traditional graphics, you can also specify the position of the inset with coordinates: POSITION$=(x,y)$. The coordinates can be given in axis percent units (the default) or in axis data units.

Data Unit Coordinates

If you specify the DATA option immediately following the coordinates, the inset is positioned using axis data units. For example, the following statements place the bottom left corner of the inset at 2 on the horizontal axis and 0.04 on the vertical axis:

ods graphics off;
title 'Mean Chart for Diameters';
proc anom data=LabelDeviations;
   xchart Deviation*Position;
   inset n /
      header   = 'Position=(2,0.04)'
      height   = 3
      position = (2,0.04) data;
run;

The ANOM chart is displayed in FigureĀ 4.33. By default, the specified coordinates determine the position of the bottom left corner of the inset. You can change this reference point with the REFPOINT= option, as in the next example.

Figure 4.33: Inset Positioned Using Data Unit Coordinates

Inset Positioned Using Data Unit Coordinates


Axis Percent Unit Coordinates

If you do not use the DATA option, the inset is positioned using axis percent units. The coordinates of the bottom left corner of the display are $(0,0)$, while the upper right corner is $(100,100)$. For example, the following statements create an ANOM chart with two insets, both positioned using coordinates in axis percent units:

title 'Mean Chart for Diameters';
proc anom data=LabelDeviations;
   xchart Deviation*Position;
   inset mean / position = (5,25)
                header   = 'Position=(5,25)'
                height   = 3
                cfill   = ywh
                refpoint = tl;
   inset mse / position = (95,95)
               header   = 'Position=(95,95)'
               height   = 3
               cfill    = ywh
               refpoint = tr;
run;

The display is shown in FigureĀ 4.34. Notice that the REFPOINT= option is used to determine which corner of the inset is to be placed at the coordinates specified with the POSITION= option. The first inset has REFPOINT=TL, so the top left corner of the inset is positioned 5% of the way across the horizontal axis and 25% of the way up the vertical axis. The second inset has REFPOINT=TR, so the top right corner of the inset is positioned 95% of the way across the horizontal axis and 95% of the way up the vertical axis. Note also that coordinates in axis percent units must be between 0 and 100.

Figure 4.34: Inset Positioned Using Axis Percent Unit Coordinates

Inset Positioned Using Axis Percent Unit Coordinates