Note: See Applying Tests with Multiple Control Limits in the SAS/QC Sample Library.

This example is a continuation of the previous example, except that distinct control limits are displayed for each of the phases determined by the variable System. The control limit parameters (mean, standard deviation, and nominal sample size) for each phase (manufacturing system) are provided in the following data set:

data Syslim;
   length _var_ $8 _subgrp_ $8 _type_ $8 _index_ $1;
   input _var_ _subgrp_ _index_ _type_ _mean_ _stddev_
         _limitn_ _sigmas_;
   datalines;
Offset Sample R standard 20.5 2.02 5 3
Offset Sample Q standard 20.2 2.35 7 3
Offset Sample T standard 20.0 2.24 5 3
;

The following statements read the control limit parameters from Syslim and use the READPHASES= and READINDEXES= options to display a distinct set of control limits for each phase:

ods graphics off;
title 'System-Specific Control Limits';
proc shewhart
   limits=Syslim
   history=Assembly (rename=(System=_phase_));
   xrchart Offset * Sample /
      tests       = 1 to 4
      testlabel   = ( comment )
      readindexes = ('T' 'R' 'Q')
      readphases  = ('T' 'R' 'Q')
      phaselegend
      phaseref
      phasebreak
      vaxis       = 16 to 26 by 2
      split       = '/' ;
   label OffsetX = 'Avg Offset in cm/Range';
run;

The chart is shown in Figure 17.184. The tests requested with the TESTS= option are applied strictly within the phases, since the control limits are not constant across the phases (as in Figure 17.183). In particular, note that the pattern labeled Reset Tool in Figure 17.183 is not detected in Figure 17.184.

In most applications involving multiple control limits, a known change or improvement has occurred at the beginning of each phase; consequently, it is appropriate to restart the tests at the beginning of each phase rather than search for patterns that span the boundaries of consecutive phases. In these situations, the PHASEBREAK option is useful for suppressing the connection of points from one phase to the next. Note that it is not necessary to specify the TESTNMETHOD= option here because the subgroup sample sizes are constant within each phase.

There may be applications in which it is appropriate to apply the tests across phase boundaries. You can use the TESTACROSS option to request this behavior.

ods graphics off;
title 'System-Specific Control Limits';
proc shewhart
   limits=Syslim
   history=Assembly (rename=(System=_phase_));
   xrchart Offset * Sample /
      tests       = 1 to 4
      testlabel   = ( comment )
      testnmethod = standardize
      testacross
      readindexes = ('T' 'R' 'Q')
      readphases  = ('T' 'R' 'Q')
      phaselegend
      phaseref
      vaxis       = 16 to 26 by 2
      split       = '/';
   label OffsetX = 'Avg Offset in cm/Range';
run;

The chart created with the TESTACROSS option is displayed in Figure 17.185.

Here, it is necessary to specify TESTNMETHOD=STANDARDIZE in conjunction with the TESTACROSS option, since the subgroup sample sizes are not constant across phases.

Although Test 3 is now signaled at sample 18, this result should be interpreted with care since the test is applied to standardized average offsets, and the averages for samples 13, 14, and 15 are standardized differently than the averages for samples 16, 17, and 18. If, for instance, the value of _MEAN_ for phase 'R' in Syslim were 21.0 rather than 20.5, the standardized mean for sample 16 would be less than the standardized mean for sample 15, and Test 3 would not be signaled at sample 18.

In summary, when working with multiple control limits, you should