Example 7.3 Factorial Design with Center Points

Note: See A Factorial Design with Center Points in the SAS/QC Sample Library.

Factorial designs that involve two levels are the most popular experimental designs. For two-level designs, it is assumed that the response is close to linear over the range of the factor levels. To check for curvature and to obtain an independent estimate of error, you can replicate points at the center of a two-level design. Adding center points to the design does not affect the estimates of factorial effects.

To construct a design with center points, you first create a data set with factorial points by using the FACTEX procedure and then augment it with center points by using a simple DATA step. The following example illustrates this technique.

A researcher is studying the effect of three 2-level factors—current (Current), voltage (Voltage), and time (Time)—by conducting an experiment using a complete factorial design. The researcher is interested in studying the overall curvature over the range of factor levels by adding four center points.

You can construct this design in two stages. First, create the basic $2^3$ design with the following statements:

proc factex;
   factors Current Voltage Time;
   output out=Factorial
          Current nvals=(12  28)
          Voltage nvals=(100 200)
          Time    nvals=(50  60);
run;

Next, create the center points and append to the basic design as follows:

data Center(drop=i);
   do i = 1 to 4;
      Current = 20;
      Voltage = 150;
      Time    = 55;
      output;
   end;
data CPDesign;
   set Factorial Center;
run;
proc print data=CPDesign;
run;

The design saved in the data set CPDesign is displayed in Output 7.3.1. Observations 1 to 8 are the factorial points, and observations 9 to 12 are the center points.

Output 7.3.1: A $2^3$ Design with Four Center Points

Obs Current Voltage Time
1 12 100 50
2 12 100 60
3 12 200 50
4 12 200 60
5 28 100 50
6 28 100 60
7 28 200 50
8 28 200 60
9 20 150 55
10 20 150 55
11 20 150 55
12 20 150 55