Factory Planning 2: When Should Machines Be Down for Maintenance

For completeness, all statements are shown. Statements that are new or changed from Chapter 3 are indicated.

proc optmodel;
   set <str> PRODUCTS;
   num profit {PRODUCTS};
   read data product_data into PRODUCTS=[product] profit;

   set PERIODS;
   num demand {PRODUCTS, PERIODS};
   read data demand_data into PERIODS=[_N_]
      {product in PRODUCTS} <demand[product,_N_]=col(product)>;

   set <str> MACHINE_TYPES;
   num num_machines {MACHINE_TYPES};

The following statements declare and populate the num_machines_needing_maintenance parameter:

   num num_machines_needing_maintenance {MACHINE_TYPES};
   read data machine_type_data into MACHINE_TYPES=[machine_type]
      num_machines num_machines_needing_maintenance;

The following statements are the same as in Chapter 3:

   num production_time {PRODUCTS, MACHINE_TYPES};
   read data machine_type_product_data into [machine_type]
      {product in PRODUCTS}
      <production_time[product,machine_type]=col(product)>;

   var Make {PRODUCTS, PERIODS} >= 0;
   var Sell {product in PRODUCTS, period in PERIODS} >= 0
      <= demand[product,period];

   num last_period = max {period in PERIODS} period;
   var Store {PRODUCTS, PERIODS} >= 0 <= &store_ub;
   for {product in PRODUCTS}
      fix Store[product,last_period] = &final_storage;

   impvar StorageCost =
      sum {product in PRODUCTS, period in PERIODS}
         &storage_cost_per_unit * Store[product,period];
   max TotalProfit =
      sum {product in PRODUCTS, period in PERIODS}
         profit[product] * Sell[product,period]
    - StorageCost;

Most of the remaining statements are new or modified from Chapter 3. The INTEGER option in the following VAR statement declares NumMachinesDown to be an integer variable:

   var NumMachinesDown {MACHINE_TYPES, PERIODS} >= 0 integer;

   con Machine_hours_con {machine_type in MACHINE_TYPES, period in PERIODS}:
      sum {product in PRODUCTS}
         production_time[product,machine_type] * Make[product,period]
   <= &num_hours_per_period *
      (num_machines[machine_type] - NumMachinesDown[machine_type,period]);

   con Maintenance_con {machine_type in MACHINE_TYPES}:
      sum {period in PERIODS} NumMachinesDown[machine_type,period]
    = num_machines_needing_maintenance[machine_type];

   con Flow_balance_con {product in PRODUCTS, period in PERIODS}:
      (if period - 1 in PERIODS then Store[product,period-1] else 0)
    + Make[product,period]
    = Sell[product,period] + Store[product,period];

Because the problem contains integer variables, the SOLVE statement automatically invokes the MILP solver:

   solve;
   print Make Sell Store;
   print NumMachinesDown;
   create data sol_data1 from [product period] Make Sell Store;
   create data sol_data2 from [machine_type period] NumMachinesDown;
quit;

The solver determines when machines should be down and obtains a total profit of £108,855, as shown in Figure 4.1. This objective value represents an increase of £15,140 from the optimal objective in Chapter 3.

As expected, the optimal numbers of machines down differ from the num_machines_down_per_period parameter values in Chapter 3.